[binutils-gdb] configure, Darwin: Ensure overrides to host-pie are passed to gcc configure.

[binutils-gdb] configure, Darwin: Ensure overrides to host-pie are passed to gcc configure.

[Alan Modra]

https://sourceware.org/git/gitweb.cgi?p=binutils-gdb.git;h=ed0a861b072c94b686c5078a7d323cd96e67a0c1

commit ed0a861b072c94b686c5078a7d323cd96e67a0c1
Author: Iain Sandoe <iain@sandoe.co.uk>
Date:   Mon Aug 7 13:07:14 2023 +0200

    configure, Darwin: Ensure overrides to host-pie are passed to gcc configure.
    
    The latest versions of Darwin on the Aarch64 platform mandate PIE executables.
    On x86_64 it remains optional, but produces tool warnings after Darwin20, so
    we default to PIE executables there too.
    
    All (non-PowerPC) 64b Darwin platforms mandate PIC code and therefore force
    host_shared on (we issue a diagnostic if the user tries to configure them
    non-shared).
    
    However, this also means we cannot test the host_shared setting independently
    of the host_pie setting so that the logic for setting PICFLAG must be amended
    for Darwin.
    
    For Darwin versions required to have PIE executables, in the event that the
    user tries to configure these as --disable-host-pie, we issue a warning and
    override the setting.  These versions must also switch host_pie on even if it
    is not given in the configure line.  To cater for this we pass the current
    value of host_pie, as determined by top-level configure, to the GCC configure.
    
    Signed-off-by: Iain Sandoe <iain@sandoe.co.uk>
    
            * Makefile.def: Pass the enable-host-pie value to GCC configure.
            * configure.ac: Adjust the logic for shared and PIE host flags to
            ensure that PIE is passed for hosts that require it.

Diff:
---
 Makefile.def |  3 ++-
 configure.ac | 44 ++++++++++++++++++++++++++++++++------------
 2 files changed, 34 insertions(+), 13 deletions(-)

diff --git a/Makefile.def b/Makefile.def
index de86056042a..705602ce0f4 100644
--- a/Makefile.def
+++ b/Makefile.def
@@ -47,7 +47,8 @@ host_modules= { module= fixincludes; bootstrap=true;
 host_modules= { module= flex; no_check_cross= true; };
 host_modules= { module= gas; bootstrap=true; };
 host_modules= { module= gcc; bootstrap=true; 
-		extra_make_flags="$(EXTRA_GCC_FLAGS)"; };
+		extra_make_flags="$(EXTRA_GCC_FLAGS)";
+		extra_configure_flags='@gcc_host_pie@'; };
 host_modules= { module= gmp; lib_path=.libs; bootstrap=true;
 		// Work around in-tree gmp configure bug with missing flex.
 		extra_configure_flags='--disable-shared LEX="touch lex.yy.c" @host_libs_picflag@';
diff --git a/configure.ac b/configure.ac
index 90a94480ec5..ba9c33e5f98 100644
--- a/configure.ac
+++ b/configure.ac
@@ -1987,27 +1987,35 @@ AC_ARG_ENABLE(linker-plugin-flags,
   extra_linker_plugin_flags=)
 AC_SUBST(extra_linker_plugin_flags)
 
-# Enable --enable-host-pie.
-# Checked early to determine whether jit is an 'all' language
+# Handle --enable-host-pie
+# If host PIE executables are the default (or must be forced on) for some host,
+# we must pass that configuration to the gcc directory.
+gcc_host_pie=
 AC_ARG_ENABLE(host-pie,
 [AS_HELP_STRING([--enable-host-pie],
 		[build position independent host executables])],
 [host_pie=$enableval
  case $host in
-   x86_64-*-darwin* | aarch64-*-darwin*)
+   *-*-darwin2*)
      if test x$host_pie != xyes ; then
-       # PIC is the default, and actually cannot be switched off.
-       echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
+       # for Darwin20+ this is required.
+       AC_MSG_WARN([PIE executables are required for the configured host, host-pie setting ignored.])
        host_pie=yes
+       gcc_host_pie=--enable-host-pie
      fi ;;
   *) ;;
  esac],
 [case $host in
-  *-*-darwin2*) host_pie=yes ;;
+  *-*-darwin2*)
+    # Default to PIE (mandatory for aarch64).
+    host_pie=yes
+    gcc_host_pie=--enable-host-pie
+    ;;
   *) host_pie=no ;;
  esac])
 
 AC_SUBST(host_pie)
+AC_SUBST(gcc_host_pie)
 
 # Enable --enable-host-shared.
 # Checked early to determine whether jit is an 'all' language
@@ -2019,27 +2027,39 @@ AC_ARG_ENABLE(host-shared,
    x86_64-*-darwin* | aarch64-*-darwin*)
      if test x$host_shared != xyes ; then
        # PIC is the default, and actually cannot be switched off.
-       echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
+       AC_MSG_WARN([PIC code is required for the configured host; host-shared setting ignored.])
        host_shared=yes
      fi ;;
    *-*-darwin*)
-     if test x$host_pie == xyes ; then
-       echo configure.ac: warning: PIC code is required for PIE executables. 1>&2
+     if test x$host_pie = xyes -a x$host_shared != xyes ; then
+       AC_MSG_WARN([PIC code is required for PIE host executables host-shared setting ignored.])
        host_shared=yes
      fi ;;
   *) ;;
  esac],
 [case $host in
+  # 64B x86_64 and Aarch64 Darwin default to PIC.
   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
-  # Darwin needs PIC objects to link PIE executables.
-  *-*-darwin*) host_shared=host_pie ;;
+  # 32B and powerpc64 Darwin must use PIC to link PIE exes.
+  *-*-darwin*) host_shared=$host_pie ;;
   *) host_shared=no;;
  esac])
 
 AC_SUBST(host_shared)
 
 if test x$host_shared = xyes; then
-  PICFLAG=-fPIC
+  case $host in
+    *-*-darwin*)
+      # Since host shared is the default for 64b Darwin, and also enabled for
+      # host_pie, ensure that we present the PIE flag when host_pie is active.
+      if test x$host_pie = xyes; then
+        PICFLAG=-fPIE
+      fi
+      ;;
+    *)
+      PICFLAG=-fPIC
+      ;;
+  esac
 elif test x$host_pie = xyes; then
   PICFLAG=-fPIE
 else