public inbox for dominion-hackers@sourceware.org
 help / color / mirror / Atom feed
* Updates to Makefile.am/configure.ac for 7.3/8.0
@ 2002-12-14 12:25 Stephen Smoogen
  0 siblings, 0 replies; only message in thread
From: Stephen Smoogen @ 2002-12-14 12:25 UTC (permalink / raw)
  To: dominion-hackers

[-- Attachment #1: Type: text/plain, Size: 749 bytes --]

Have made a new configure.am and some changes to Makefile.am to allow it
to compile on a RHL 8.0 machine. This requires autoconf-2.53 and
automake-1.6 for it to complete. Both are available with RHL-7.3 also.

Steps for compilation: 

save Makefile.am and configure.ac to /tmp 

tar xzvf dominion-2.6b.tgz 
mv dominion-2.6b dominion-2.6c-alpha 
cd dominion-2.6c-alpha 
rm acconfig.h configure.in 
cp /tmp/Makefile.am . 
cp /tmp/configure.ac . 

autoreconf-2.53 -ivh 

then make and install.. working on the next set of things to clear up
some old fgets and such. 

--------------------------- 


-- 
Stephen John Smoogen		smoogen@lanl.gov
Los Alamos National Labrador  CCN-2 B-Schedule  PH: 
Ta-03 SM-261  MailStop P208 DP 17U  Los Alamos, NM 87545

[-- Attachment #2: Makefile.am --]
[-- Type: text/x-makefile, Size: 3708 bytes --]

## Process this file with automake to produce Makefile.in

bin_PROGRAMS = dominion dom_make dom_add dom_update dom_print

bin_SCRIPTS = addnews.sh make-new-world.sh

info_TEXINFOS = dominion.texi

dominion_SOURCES = dominion.c world.c nation.c user.c ext.c file.c misc.c \
	init.c budget.c techno.c commands.c help.c menus.c diplomacy.c \
	reports.c spy.c army.c armylib.c mail.c diplolib.c maglib.c \
	cur_stuff.c news.c c_news.c economy.c transport.c spells.c \
	spelllib.c root.c cinfo.c construct.c int_mail.c movement.c \
	bonds.c bondslib.c cn_params.c

dom_make_SOURCES = makeworld.c file.c misc.c ext.c armylib.c diplolib.c \
	world.c economy.c movement.c bondslib.c cn_params.c

dom_add_SOURCES = addnation.c file.c misc.c ext.c armylib.c diplolib.c \
	world.c economy.c movement.c bondslib.c cn_params.c

dom_update_SOURCES = update.c file.c misc.c nation.c armylib.c ext.c mail.c \
	techno.c battle.c diplolib.c world.c maglib.c cn_params.c cn.c \
	economy.c spelllib.c news.c movement.c cnlib.c bondslib.c

dom_print_SOURCES = printmap.c file.c misc.c nation.c armylib.c ext.c maglib.c\
	diplolib.c world.c economy.c movement.c spelllib.c bondslib.c \
	cn_params.c

BUILT_SOURCES = config.h

noinst_HEADERS = army.h common.h cur_stuff.h dominion.h proto.h bonds.h \
	decl.h misc.h cn.h costs.h dom_config.h news.h

# The non-source data files are: magic stuff, misc and doc stuff

magic_DATA = mag_Aule mag_Demonology mag_Insects mag_Necromancy mag_Unity \
	mag_Avian mag_Diana mag_Master mag_Neptune mag_Yavanna mag_Chess \
	mag_Inferno mag_Monsters mag_Time mag_orders
magicdir = $(libdir)/dominion/magic

misc_DATA = races cns cns.small army_types spirit_types techno_levels
miscdir = $(libdir)/dominion/misc

# play_doc is the documentation that is used while playing
# play_doc_DATA = dominion.info info_intro refcard
play_doc_DATA = dominion.info info_intro refcard
play_docdir = $(libdir)/dominion/doc

# the next rule is to create certain subdirectories that don't really get
# any files put in them by default
install-data-local:
	-$(mkinstalldirs) $(libdir)/dominion/exec
	-$(mkinstalldirs) $(libdir)/dominion/options
	-$(mkinstalldirs) $(libdir)/dominion/params
	-$(mkinstalldirs) $(libdir)/dominion/mail
	-$(mkinstalldirs) $(libdir)/dominion/news

man_MANS = dominion.6
EXTRA_DIST = config.rpath mkinstalldirs  config.rpath  MACHINES TASKS dominion.tex gm.tex dominion.info gm.info \
	tabular.sty latexinfo.sty addnews.sh make-new-world.sh $(DATA)

#CFLAGS = -DVERSION=\"$(VERSION)\" -DDEF_LIBDIR=\"$(libdir)/dominion\" -g
CFLAGS = -DDEF_LIBDIR=\"$(libdir)/dominion\" -g

gm.info: gm.tex
	echo "You cannot make gm.info from this Makefile"
	echo "Please contact the Dominion authors, or get the latexinfo"
	echo "package."
#dominion.info: dominion.tex
#	echo "You cannot make dominion.info from this Makefile"
#	echo "Please contact the Dominion authors, or get the latexinfo"
#	echo "package."

gm.dvi: gm.tex
	latex gm.tex
	latex gm.tex		# run latex twice to get the indices right
#dominion.dvi: dominion.tex
#	latex dominion.tex
#	latex dominion.tex	# run latex twice to get the indices right

gm.ps: gm.dvi
	dvips gm.dvi
#dominion.ps: dominion.dvi
#	dvips dominion.dvi

# this rule makes a new world; [FIXME] it should be replaced with a
# shell script eventually
new-world: all install
	@echo
	@echo 'all data cleared, and lib files installed'
	@echo
	./dom_make -d $(libdir)/dominion
	@echo 'newsgroup ' News ' created automatically'
	-mkdir $(libdir)/dominion/news/News
	@echo News ' 1 0 0' > $(libdir)/dominion/news/groups
	/bin/sh ./addnews.sh $(libdir)/dominion/news groups



[-- Attachment #3: configure.ac --]
[-- Type: text/plain, Size: 2544 bytes --]

dnl configure.in script for the dominion program
dnl original author: Mark Galassi
dnl modified by: Stephen J Smoogen
dnl license: GNU GENERAL PUBLIC LICENSE version 2
dnl -------------------------------------------------------------
dnl Process this file with autoconf to produce the configure script.
dnl
AC_INIT([dominion],[2.6c-0.1],[smoogen@lanl.gov],[dominion-2.6c-0.1.tar.gz])

dnl Unique file to test on and end result config file
AC_CONFIG_SRCDIR([dominion.c])
AM_CONFIG_HEADER([config.h])
AM_INIT_AUTOMAKE

dnl Require Autoconf-2.53
AC_PREREQ(2.53)

dnl Copyright notice
AC_COPYRIGHT(GPL v2.0)

dnl Revision notice
AC_REVISION($Revision: 0.10 $)

dnl turn off maintainer removal of configure script
dnl AM_MAINTAINER_MODE

dnl -------------------------------------------------------------
dnl locate C compiler and Make tools
AC_PROG_CC
AC_PROG_MAKE_SET
AC_PROG_INSTALL

dnl not currently needed but will be needed when client and server are
dnl split apart and common libraries are needed
dnl AC_PROG_LIBTOOL

dnl -------------------------------------------------------------
dnl look for posix compliance on some platforms
AC_ISC_POSIX

AC_DEFINE([PREFIX], "${prefix}", [define for path prefix])
AC_DEFINE([INFO_PATH], "${prefix}/info", [define for path info])
AC_DEFINE([INFO_INTRO], "${prefix}/lib/dominion/doc/info_intro", [define for intro])
AC_DEFINE([VERSION], "$VERSION", [define for version])

AC_SUBST(CFLAGS)
AC_SUBST(CPPFLAGS)
AC_SUBST(LDFLAGS)

dnl -------------------------------------------------------------
dnl Check for programs
dnl  Email programs
AC_CHECK_PROGS(MAIL_PROG, Mail mailx elm pine)


dnl -------------------------------------------------------------
dnl Checks for header files.
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS([fcntl.h limits.h netinet/in.h stdlib.h string.h strings.h unistd.h])

dnl -------------------------------------------------------------
dnl Check for typedefs, structures, and compiler characteristics.

dnl Checks for libraries.
AC_CHECK_LIB(termcap, main)
AC_CHECK_LIB(ncurses, main)
AC_CHECK_LIB(curses, main)
AC_CHECK_LIB(m, main)
AC_CHECK_LIB(crypt, main)

dnl -------------------------------------------------------------
dnl Check for library functions
AC_FUNC_CHOWN
AC_FUNC_FORK
AC_FUNC_MALLOC
AC_FUNC_VPRINTF
AC_TYPE_SIGNAL
AC_CHECK_FUNCS([alarm crypt getcwd gethostname getpass getwd memset pow sqrt strchr strrchr strstr srandom srand48])

AC_CONFIG_FILES([Makefile])
AC_OUTPUT

^ permalink raw reply	[flat|nested] only message in thread

only message in thread, other threads:[~2002-12-14 20:25 UTC | newest]

Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2002-12-14 12:25 Updates to Makefile.am/configure.ac for 7.3/8.0 Stephen Smoogen

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).