Re: [Patch, fortran] PR96320 - gfortran 8-10 shape mismatch in assumed-length dummy argument character array

[Paul Richard Thomas <paul.richard.thomas@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 1269 bytes --]

Sorry, the testcases were left off.

Paul


On Wed, 6 Jan 2021 at 20:23, Paul Richard Thomas <
paul.richard.thomas@gmail.com> wrote:

> This patch fixes the problems in comments 23 and 24 of the PR.
>
> Comment 23 is fixed by the chunk in expr.c. The chunks in decl.c and
> resolve.c fix #24. To be quite honest, I am not sure why they were not
> needed in the first place! However, the changes don't cause any problems.
> Removing the interface bodies causes the expected error cascade.
>
> Regtests on FC33/x86_64 - OK for master and, after a decent delay 9- and
> 10- branches?
>
> Paul
>
> Fortran: This patch fixes comments 23 and 24 of PR96320.
>
> 2021-01-06  Paul Thomas  <pault@gcc.gnu.org>
>
> gcc/fortran
> PR fortran/96320
> * decl.c (gfc_match_modproc): It is not an error to find a
> module procedure declaration within a contains block.
> * expr.c (gfc_check_vardef_context): Pure procedure result is
> assignable. Change 'own_scope' accordingly.
> * resolve.c (resolve_typebound_procedure): A procedure that
> has the module procedure attribute is almost certainly a
> module procedure, whatever its interface.
>
> gcc/testsuite/
> PR fortran/96320
> * gfortran.dg/module_procedure_5.f90 : New test.
> * gfortran.dg/module_procedure_6.f90 : New test.
>

[-- Attachment #2: module_procedure_5.f90 --]
[-- Type: text/x-fortran, Size: 604 bytes --]

! { dg-do compile }
!
! Test the fix for the testcase in comment 23 of PR96320, which used to
! fail with the message: Variable ‘new_foo’ cannot appear in a variable
! definition context.
!
! Contributed by Damian Rouson  <damian@sourceryinstitute.org>
!
module foobar
  implicit none

  type foo
    integer bar
  end type

  interface
    pure module function create() result(new_foo)
      implicit none
      type(foo) new_foo
    end function
  end interface

contains
  module procedure create
    new_foo%bar = 1  ! Error here
  end procedure
end module

  use foobar
  print *, create ()
end

[-- Attachment #3: module_procedure_6.f90 --]
[-- Type: text/x-fortran, Size: 1421 bytes --]

! { dg-do run }
!
! Test the fix for the testcase in comment 24 of PR96320, which used to
! fail with the message: ‘set_user_defined’ must be a module procedure or
! an external procedure with an explicit interface at (1)
!
! Contributed by Damian Rouson  <damian@sourceryinstitute.org>
!
module hole_interface
  type hole_t
    integer :: user_defined
    real :: hole_diameter
  contains
    procedure set_user_defined
    procedure set_diameter
  end type

  interface
    module subroutine set_diameter (this, diameter)
      class(hole_t) :: this
      real :: diameter
    end subroutine

    module subroutine set_user_defined(this, user_defined)
      class(hole_t) :: this
      integer :: user_defined
    end subroutine
  end interface

contains
  module procedure set_user_defined
    this%user_defined = user_defined
  end procedure

  module procedure set_diameter
    this%hole_diameter = diameter
    if (this%user_defined .lt. 0) then
      call this%set_user_defined (0)
    end if
  end procedure
end module

  use hole_interface ! Error was here
  type (hole_t) :: ht = hole_t (-1, 0.0)
  call ht%set_diameter(1.0)
  if ((ht%user_defined .ne. 0) .and. (ht%hole_diameter .ne. 1.0)) stop 1
  call ht%set_user_defined (5)
  if ((ht%user_defined .ne. 5) .and. (ht%hole_diameter .ne. 1.0)) stop 2
  call ht%set_diameter(2.0)
  if ((ht%user_defined .ne. 5) .and. (ht%hole_diameter .ne. 2.0)) stop 3
end