public inbox for gcc-bugs@sourceware.org
help / color / mirror / Atom feed
* [Bug fortran/44863]  New: Fortran runtime error: internal error: bad hash value in dynamic dispatch
@ 2010-07-08  2:09 david dot car7 at gmail dot com
  2010-07-08  2:11 ` [Bug fortran/44863] " david dot car7 at gmail dot com
                   ` (4 more replies)
  0 siblings, 5 replies; 6+ messages in thread
From: david dot car7 at gmail dot com @ 2010-07-08  2:09 UTC (permalink / raw)
  To: gcc-bugs

[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1: Type: text/plain, Size: 4724 bytes --]

The following code compiles fine but produces a runtime error when trying to
perform a dynamic dispatch:

!================================================================
module BaseStrategy

  type, public, abstract :: Strategy
   contains
     procedure(strategy_update), pass( this ), deferred :: update
     procedure(strategy_pre_update), pass( this ), deferred :: preUpdate
     procedure(strategy_post_update), pass( this ), deferred :: postUpdate
  end type Strategy

  abstract interface
     subroutine strategy_update( this )
       import Strategy
       class (Strategy), target, intent(in) :: this
     end subroutine strategy_update
  end interface

  abstract interface
     subroutine strategy_pre_update( this )
       import Strategy
       class (Strategy), target, intent(in) :: this
     end subroutine strategy_pre_update
  end interface

  abstract interface
     subroutine strategy_post_update( this )
       import Strategy
       class (Strategy), target, intent(in) :: this
     end subroutine strategy_post_update
  end interface

end module BaseStrategy

!==============================================================
module LaxWendroffStrategy

  use BaseStrategy

  private :: update, preUpdate, postUpdate

  type, public, extends( Strategy ) :: LaxWendroff
     class (Strategy), pointer :: child => null()
     contains
       procedure, pass( this ) :: update
       procedure, pass( this ) :: preUpdate
       procedure, pass( this ) :: postUpdate
  end type LaxWendroff

contains

  subroutine update( this )
    class (LaxWendroff), target, intent(in) :: this

    print *, 'Calling LaxWendroff update'
  end subroutine update

  subroutine preUpdate( this )
    class (LaxWendroff), target, intent(in) :: this

    print *, 'Calling LaxWendroff preUpdate'
  end subroutine preUpdate

  subroutine postUpdate( this )
    class (LaxWendroff), target, intent(in) :: this

    print *, 'Calling LaxWendroff postUpdate'
  end subroutine postUpdate

end module LaxWendroffStrategy
!===============================================================
module KEStrategy

  use BaseStrategy
  ! Uncomment the line below and it runs fine                                   
  ! use LaxWendroffStrategy                                                     

  private :: update, preUpdate, postUpdate

  type, public, extends( Strategy ) :: KE
     class (Strategy), pointer :: child => null()
     contains
       procedure, pass( this ) :: update
       procedure, pass( this ) :: preUpdate
       procedure, pass( this ) :: postUpdate
  end type KE

contains

  subroutine init( this, other )
    class (KE), intent(inout) :: this
    class (Strategy), target, intent(in) :: other

    this % child => other
  end subroutine init

  subroutine update( this )
    class (KE), target, intent(in) :: this

    if ( associated( this % child ) ) then
       call this % child % update()
    end if

    print *, 'Calling KE update'
  end subroutine update

 subroutine preUpdate( this )
    class (KE), target, intent(in) :: this

    if ( associated( this % child ) ) then
       call this % child % preUpdate()
    end if

    print *, 'Calling KE preUpdate'
  end subroutine preUpdate

  subroutine postUpdate( this )
    class (KE), target, intent(in) :: this

    if ( associated( this % child ) ) then
       call this % child % postUpdate()
    end if

    print *, 'Calling KE postUpdate'
  end subroutine postUpdate

end module KEStrategy

!=============================================================                
program main

  use LaxWendroffStrategy
  use KEStrategy

  type :: StratSeq
     class (Strategy), pointer :: strat => null()
  end type StratSeq

  type (LaxWendroff), target :: lw_strat
  type (KE), target :: ke_strat

  allocate( seq(10) )

  call init( ke_strat, lw_strat )
  call ke_strat % preUpdate()
  call ke_strat % update()
  call ke_strat % postUpdate()                 

end program main

The specific runtime error is:

At line 111 of file test.f90
Fortran runtime error: internal error: bad hash value in dynamic dispatch

Line 111 above is the line:
       call this % child % preUpdate()

If I uncomment the line the comment "! Uncomment the line below and it runs
fine" the code builds and runs without an error.


-- 
           Summary: Fortran runtime error: internal error: bad hash value in
                    dynamic dispatch
           Product: gcc
           Version: 4.5.1
            Status: UNCONFIRMED
          Severity: normal
          Priority: P3
         Component: fortran
        AssignedTo: unassigned at gcc dot gnu dot org
        ReportedBy: david dot car7 at gmail dot com


http://gcc.gnu.org/bugzilla/show_bug.cgi?id=44863


^ permalink raw reply	[flat|nested] 6+ messages in thread
end of thread, other threads:[~2010-08-21 15:00 UTC | newest]

Thread overview: 6+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2010-07-08  2:09 [Bug fortran/44863] New: Fortran runtime error: internal error: bad hash value in dynamic dispatch david dot car7 at gmail dot com
2010-07-08  2:11 ` [Bug fortran/44863] " david dot car7 at gmail dot com
2010-07-08  7:23 ` burnus at gcc dot gnu dot org
2010-07-10  8:35 ` [Bug fortran/44863] [OOP] " janus at gcc dot gnu dot org
2010-08-21 14:51 ` janus at gcc dot gnu dot org
2010-08-21 15:00 ` janus at gcc dot gnu dot org

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).