[libgfortran,patch] New autoconf test

[libgfortran,patch] New autoconf test

[François-Xavier Coudert]

Hi all,

I'd like to have the opinion of a autoconf or build machinery expert
on this patch. I'm trying to add a test in libgfortran/configure.ac to
check that the gfortran compiler that was just built (before the
target libraries) is working, and if not, issue a clear error message.
The following patch appears to do just this on my i686-linux setup,
but
  a) is it the right way of doing this?
  b) would it work in a cross-compiler setup?

Index: libgfortran/acinclude.m4
===================================================================
--- libgfortran/acinclude.m4    (revision 120585)
+++ libgfortran/acinclude.m4    (working copy)
@@ -1,6 +1,24 @@
 m4_include(../config/acx.m4)
 m4_include(../config/no-executables.m4)

+dnl Check that we have a working GNU Fortran compiler
+AC_DEFUN([LIBGFOR_WORKING_GFORTRAN], [
+  AC_MSG_CHECKING([whether the GNU Fortran compiler is working])
+  cat > conftest.f90 <<EOF
+    program foo
+      real, parameter :: bar = sin(12.34)
+    end program foo
+EOF
+  if ( $FC conftest.f90 -c -o conftest.o ); then
+    echo "yes"
+    rm conftest.f90 conftest.o
+  else
+    AC_MSG_ERROR(GNU Fortran is not working; error message is printed above)
+    rm conftest.f90
+  fi
+])
+
+
 dnl Check:
 dnl * If we have gettimeofday;
 dnl * If we have struct timezone for use in calling it;
Index: libgfortran/configure.ac
===================================================================
--- libgfortran/configure.ac    (revision 120585)
+++ libgfortran/configure.ac    (working copy)
@@ -143,6 +143,10 @@
 FC="$GFORTRAN"
 AC_PROG_FC(gfortran)

+# We need a working compiler at that point, otherwise give a clear
+# error message and bail out.
+LIBGFOR_WORKING_GFORTRAN
+
 # extra LD Flags which are required for targets
 case "${host}" in
   *-darwin*)


For gfortran developers: the reason why we need to do that is that
people sometime get an unusable f951 (liked with a wrong mpfr library,
or that doesn't work because LD_LIBRARY_PATH is not set correctly) and
in that case, they currently don't have a clear error message but a
rather cryptic error while compiling the library. See PR 26893
(especially the last comments).

Thanks,
FX

Re: [libgfortran,patch] New autoconf test

[Paolo Bonzini]

François-Xavier Coudert wrote:
> Hi all,
> 
> I'd like to have the opinion of a autoconf or build machinery expert
> on this patch. I'm trying to add a test in libgfortran/configure.ac to
> check that the gfortran compiler that was just built (before the
> target libraries) is working, and if not, issue a clear error message.
> The following patch appears to do just this on my i686-linux setup,
> but
>  a) is it the right way of doing this?
>  b) would it work in a cross-compiler setup?
> 
> Index: libgfortran/acinclude.m4
> ===================================================================
> --- libgfortran/acinclude.m4    (revision 120585)
> +++ libgfortran/acinclude.m4    (working copy)
> @@ -1,6 +1,24 @@
> m4_include(../config/acx.m4)
> m4_include(../config/no-executables.m4)
> 
> +dnl Check that we have a working GNU Fortran compiler
> +AC_DEFUN([LIBGFOR_WORKING_GFORTRAN], [
> +  AC_MSG_CHECKING([whether the GNU Fortran compiler is working])
> +  cat > conftest.f90 <<EOF
> +    program foo
> +      real, parameter :: bar = sin(12.34)
> +    end program foo
> +EOF
> +  if ( $FC conftest.f90 -c -o conftest.o ); then
> +    echo "yes"
> +    rm conftest.f90 conftest.o
> +  else
> +    AC_MSG_ERROR(GNU Fortran is not working; error message is printed 
> above)
> +    rm conftest.f90
> +  fi
> +])

I think something like this should work too.  Autoconf provides macros 
for compile tests:

AC_MSG_CHECKING([whether the GNU Fortran compiler is working])
AC_COMPILE_IFELSE([[
     program foo
       real, parameter :: bar = sin(12.34)
     end program foo]], ,
     [AC_MSG_RESULT([yes])],
     [AC_MSG_RESULT([no])
      AC_MSG_ERROR([GNU Fortran is not working; please report a bug in 
http://gcc.gnu.org/bugzilla, attaching `pwd`/config.log])

Paolo

Re: [libgfortran,patch] New autoconf test

[Andreas Schwab]

Paolo Bonzini <paolo.bonzini@lu.unisi.ch> writes:

> I think something like this should work too.  Autoconf provides macros for
> compile tests:
>
> AC_MSG_CHECKING([whether the GNU Fortran compiler is working])
> AC_COMPILE_IFELSE([[
>     program foo
>       real, parameter :: bar = sin(12.34)
>     end program foo]], ,
>     [AC_MSG_RESULT([yes])],
>     [AC_MSG_RESULT([no])
>      AC_MSG_ERROR([GNU Fortran is not working; please report a bug in
> http://gcc.gnu.org/bugzilla, attaching `pwd`/config.log])

Except that you have to switch the language to Fortran, by putting it
between AC_LANG_PUSH(Fortran) and  AC_LANG_POP(Fortran).

Andreas.

-- 
Andreas Schwab, SuSE Labs, schwab@suse.de
SuSE Linux Products GmbH, Maxfeldstraße 5, 90409 Nürnberg, Germany
PGP key fingerprint = 58CA 54C7 6D53 942B 1756  01D3 44D5 214B 8276 4ED5
"And now for something completely different."

Re: [libgfortran,patch] New autoconf test

[Andreas Schwab]

"François-Xavier Coudert" <fxcoudert@gmail.com> writes:

> dnl Check that we have a working GNU Fortran compiler
> AC_DEFUN([LIBGFOR_WORKING_GFORTRAN], [
> AC_MSG_CHECKING([whether the GNU Fortran compiler is working])
> AC_LANG_PUSH([Fortran])
> AC_COMPILE_IFELSE([[
>       program foo
>       real, parameter :: bar = sin (12.34 / 2.5)
>       end program foo]], ,
>     [AC_MSG_RESULT([yes])],
>     [AC_MSG_RESULT([no])
>      AC_MSG_ERROR([GNU Fortran is not working; please report a bug in
> http://gcc.gnu.org/bugzilla, attaching `pwd`/config.log])
>     ]
       ^
Missing paren.

> AC_LANG_POP([Fortran])
> ])

Andreas.

-- 
Andreas Schwab, SuSE Labs, schwab@suse.de
SuSE Linux Products GmbH, Maxfeldstraße 5, 90409 Nürnberg, Germany
PGP key fingerprint = 58CA 54C7 6D53 942B 1756  01D3 44D5 214B 8276 4ED5
"And now for something completely different."

Re: [libgfortran,patch] New autoconf test

[Paolo Bonzini]

> I did just that (acinclude.m4 and regenerated configure attached), but
> it fails in the weirdest way:

As Andreas noticed, you had missed a parenthesis.  There were a couple 
of other nits, in particular `pwd` is escaped by autoconf so you need to 
use $PWD.  The result looks like this:

AC_MSG_CHECKING([whether the GNU Fortran compiler is working])
AC_LANG_PUSH([Fortran])
AC_COMPILE_IFELSE([[
       program foo
       real, parameter :: bar = sin (12.34 / 2.5)
       end program foo]],
     [AC_MSG_RESULT([yes])],
     [AC_MSG_RESULT([no])
      AC_MSG_ERROR([GNU Fortran is not working; please report a bug in
http://gcc.gnu.org/bugzilla, attaching $PWD/config.log])
     ])
AC_LANG_POP([Fortran])


In general, if I write "something like this should work", it means 
"double check on the manual if you get some weird result".  :-)

Paolo

Re: [libgfortran,patch] New autoconf test

[François-Xavier Coudert]

> As Andreas noticed, you had missed a parenthesis.  There were a couple
> of other nits, in particular `pwd` is escaped by autoconf so you need to
> use $PWD.  The result looks like this:

Thanks Paolo and Andreas. I'll be making a formal patch submission right away.

FX