Re: [PATCH v5] [gdb/testsuite] New test: gdb.base/check-errno.exp

[Kevin Buettner <kevinb@redhat.com>]

Hi Pedro,

Thanks for your review!

On Fri, 10 May 2024 14:08:24 +0100
Pedro Alves <pedro@palves.net> wrote:

> Actually, you can also use -wrap to simplify further:
> 
>     gdb_test_multiple "ptype errno" "" {
> 	-re -wrap "type = int" {
> 	    pass $gdb_test_name
> 	}

I've made all of your suggested fixes, except for the one above.

While I can use -wrap for the above RE, if I also use it for the next
RE, I see failures when using check-read1 when testing on a machine
without glibc debuginfo.  For the moment, I've decided against using
-wrap, but if I get time, I'll revisit it and try to understand why
it's failing.

This isn't working for me:

    gdb_test_multiple "ptype errno" "check errno type availability" {
	-re -wrap "type = int" {
	    pass $gdb_test_name
	}
	-re -wrap "type = .*no debug info" {
	    pass $gdb_test_name
	    set do_xfail 1
	    set do_xfail_core_test 1
	}
	-re -wrap ".*Cannot find thread-local variables on this target" {
	    pass $gdb_test_name
	    set do_xfail 1
	    set do_xfail_core_test 1
	    set do_xfail_cast 1
	}
	-re -wrap ".*Cannot find thread-local storage" {
	    pass $gdb_test_name
	    set do_xfail 1
	    set do_xfail_core_test 1
	    set do_xfail_cast 1
	}
	-re -wrap ".*has unknown return type; cast the call to its declared return type" {

	    # On systems which glibc as the C library, using -g3,
	    # which causes macro information to be included in the
	    # debuginfo, errno might be defined as follows:
	    #
	    #   #define errno (*__errno_location ())
	    #
	    # So, when we do "ptype errno", due to macro expansion,
	    # this ends up being "ptype (*__errno_location ())".  So
	    # the call to __errno_location (or something similar on
	    # other OSes) is the call mentioned in the error message.

	    pass $gdb_test_name
	    set do_xfail 1
	    set do_xfail_core_test 1
	    set do_xfail_cast 1
	}
    }

But this is:

    gdb_test_multiple "ptype errno" "check errno type availability" {
	-re "type = int\r\n$::gdb_prompt $" {
	    pass $gdb_test_name
	}
	-re "type = .*no debug info.*$::gdb_prompt $" {
	    pass $gdb_test_name
	    set do_xfail 1
	    set do_xfail_core_test 1
	}
	-re ".*Cannot find thread-local variables on this target.*$::gdb_prompt $" {
	    pass $gdb_test_name
	    set do_xfail 1
	    set do_xfail_core_test 1
	    set do_xfail_cast 1
	}
	-re ".*Cannot find thread-local storage.*$::gdb_prompt $" {
	    pass $gdb_test_name
	    set do_xfail 1
	    set do_xfail_core_test 1
	    set do_xfail_cast 1
	}
	-re ".*has unknown return type; cast the call to its declared return type.*$::gdb_prompt $" {

	    # On systems which glibc as the C library, using -g3,
	    # which causes macro information to be included in the
	    # debuginfo, errno might be defined as follows:
	    #
	    #   #define errno (*__errno_location ())
	    #
	    # So, when we do "ptype errno", due to macro expansion,
	    # this ends up being "ptype (*__errno_location ())".  So
	    # the call to __errno_location (or something similar on
	    # other OSes) is the call mentioned in the error message.

	    pass $gdb_test_name
	    set do_xfail 1
	    set do_xfail_core_test 1
	    set do_xfail_cast 1
	}
    }

Kevin