From: Adhemerval Zanella <adhemerval.zanella@linaro.org>
To: libc-alpha@sourceware.org
Subject: [PATCH v4 20/21] nptl: csky: Fix Race conditions in pthread cancellation [BZ#12683]
Date: Fri, 3 Apr 2020 17:32:00 -0300 [thread overview]
Message-ID: <20200403203201.7494-21-adhemerval.zanella@linaro.org> (raw)
In-Reply-To: <20200403203201.7494-1-adhemerval.zanella@linaro.org>
This patch adds the csky modifications required for the BZ#12683 fix
by adding the arch-specific cancellation syscall bridge.
Checked against a build and make check run-built-tests=no for
csky-linux-gnuabiv2.
---
sysdeps/csky/nptl/tcb-offsets.sym | 3 +
sysdeps/unix/sysv/linux/csky/syscall_cancel.S | 115 ++++++++++++++++++
2 files changed, 118 insertions(+)
create mode 100644 sysdeps/unix/sysv/linux/csky/syscall_cancel.S
diff --git a/sysdeps/csky/nptl/tcb-offsets.sym b/sysdeps/csky/nptl/tcb-offsets.sym
index f1105205c0..dab7518aa4 100644
--- a/sysdeps/csky/nptl/tcb-offsets.sym
+++ b/sysdeps/csky/nptl/tcb-offsets.sym
@@ -8,3 +8,6 @@
MULTIPLE_THREADS_OFFSET thread_offsetof (header.multiple_threads)
TID_OFFSET thread_offsetof (tid)
+
+-- Not strictly offsets, used on syscall_cancel.S
+TCB_CANCELED_BITMASK CANCELED_BITMASK
diff --git a/sysdeps/unix/sysv/linux/csky/syscall_cancel.S b/sysdeps/unix/sysv/linux/csky/syscall_cancel.S
new file mode 100644
index 0000000000..a730225a22
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/csky/syscall_cancel.S
@@ -0,0 +1,115 @@
+/* Cancellable syscall wrapper. Linux/csky version.
+ Copyright (C) 2020 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+
+/* long int __syscall_cancel_arch (int *cancelhandling,
+ __syscall_arg_t nr,
+ __syscall_arg_t arg1,
+ __syscall_arg_t arg2,
+ __syscall_arg_t arg3,
+ __syscall_arg_t arg4,
+ __syscall_arg_t arg5,
+ __syscall_arg_t arg6) */
+
+#ifdef SHARED
+# define STACK_ADJ 4
+#else
+# define STACK_ADJ 0
+#endif
+
+ENTRY (__syscall_cancel_arch)
+ subi sp, sp, 16 + STACK_ADJ
+ cfi_def_cfa_offset (16 + STACK_ADJ)
+#ifdef SHARED
+ st.w gb, (sp, 16)
+ lrw t1, 1f@GOTPC
+ cfi_offset (gb, -4)
+ grs gb, 1f
+1:
+#endif
+ st.w lr, (sp, 12)
+ st.w l3, (sp, 8)
+ st.w l1, (sp, 4)
+ st.w l0, (sp, 0)
+#ifdef SHARED
+ addu gb, gb, t1
+#endif
+ subi sp, sp, 16
+ cfi_def_cfa_offset (32 + STACK_ADJ)
+ cfi_offset (lr, -( 4 + STACK_ADJ))
+ cfi_offset (l3, -( 8 + STACK_ADJ))
+ cfi_offset (l1, -(12 + STACK_ADJ))
+ cfi_offset (l0, -(16 + STACK_ADJ))
+
+ mov l3, a1
+ mov a1, a3
+ ld.w a3, (sp, 32 + STACK_ADJ)
+ st.w a3, (sp, 0)
+ ld.w a3, (sp, 36 + STACK_ADJ)
+ st.w a3, (sp, 4)
+ ld.w a3, (sp, 40 + STACK_ADJ)
+ st.w a3, (sp, 8)
+ ld.w a3, (sp, 44 + STACK_ADJ)
+ st.w a3, (sp, 12)
+
+ .globl __syscall_cancel_arch_start
+__syscall_cancel_arch_start:
+ ld.w t0, (a0, 0)
+ andi t0, t0, TCB_CANCELED_BITMASK
+ jbnez t0, 2f
+ mov a0, a2
+ ld.w a3, (sp, 4)
+ ld.w a2, (sp, 0)
+ ld.w l0, (sp, 8)
+ ld.w l1, (sp, 12)
+ trap 0
+
+ .globl __syscall_cancel_arch_end
+ .type __syscall_cancel_arch_end,@function
+__syscall_cancel_arch_end:
+ addi sp, sp, 16
+ cfi_remember_state
+ cfi_def_cfa_offset (16 + STACK_ADJ)
+#ifdef SHARED
+ ld.w gb, (sp, 16)
+ cfi_restore (gb)
+#endif
+ ld.w lr, (sp, 12)
+ cfi_restore (lr)
+ ld.w l3, (sp, 8)
+ cfi_restore (l3)
+ ld.w l1, (sp, 4)
+ cfi_restore (l1)
+ ld.w l0, (sp, 0)
+ cfi_restore (l0)
+ addi sp, sp, 16
+ cfi_def_cfa_offset (0)
+ rts
+
+2:
+ cfi_restore_state
+#ifdef SHARED
+ lrw a3, __syscall_do_cancel@GOTOFF
+ addu a3, a3, gb
+ jsr a3
+#else
+ jbsr __syscall_do_cancel
+#endif
+END (__syscall_cancel_arch)
+libc_hidden_def (__syscall_cancel_arch)
--
2.17.1
next prev parent reply other threads:[~2020-04-03 20:32 UTC|newest]
Thread overview: 46+ messages / expand[flat|nested] mbox.gz Atom feed top
2020-04-03 20:31 [PATCH v4 00/21] nptl: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 01/21] nptl: Do not close the pipe on tst-cancel{2,3} Adhemerval Zanella
2020-04-07 15:24 ` Zack Weinberg
2020-04-07 20:07 ` Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 02/21] nptl: Fix Race conditions in pthread cancellation [BZ#12683] Adhemerval Zanella
2020-04-07 18:24 ` Zack Weinberg
2020-04-08 14:13 ` Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 03/21] nptl: x86_64: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 04/21] nptl: x32: " Adhemerval Zanella
2020-04-03 21:22 ` Joseph Myers
2020-04-07 12:47 ` Adhemerval Zanella
2020-04-07 12:54 ` H.J. Lu
2020-04-07 13:33 ` Adhemerval Zanella
2020-04-07 13:40 ` H.J. Lu
2020-04-07 13:41 ` H.J. Lu
2020-04-07 13:55 ` Adhemerval Zanella
2020-04-07 13:59 ` H.J. Lu
2020-04-07 14:04 ` Adhemerval Zanella
2020-04-07 15:45 ` H.J. Lu
2020-04-07 16:16 ` Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 05/21] nptl: i386: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 06/21] nptl: ia64: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 07/21] nptl: mips: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 08/21] nptl: aarch64: " Adhemerval Zanella
2020-04-12 15:29 ` Stepan Golosunov
2020-04-15 14:30 ` Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 09/21] nptl: arm: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 10/21] nptl: powerpc: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 11/21] nptl: microblaze: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 12/21] nptl: sparc: " Adhemerval Zanella
2020-04-12 15:33 ` Stepan Golosunov
2020-04-14 16:54 ` Stepan Golosunov
2020-04-15 14:48 ` Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 13/21] nptl: hppa: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 14/21] nptl: m68k: " Adhemerval Zanella
2020-04-03 21:34 ` Andreas Schwab
2020-04-07 12:46 ` Adhemerval Zanella
2020-04-12 15:42 ` Stepan Golosunov
2020-04-15 14:51 ` Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 15/21] nptl: alpha: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 16/21] nptl: sh: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 17/21] nptl: riscv: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 18/21] nptl: s390: " Adhemerval Zanella
2020-04-03 20:31 ` [PATCH v4 19/21] nptl: nios2: " Adhemerval Zanella
2020-04-03 20:32 ` Adhemerval Zanella [this message]
2020-04-03 20:32 ` [PATCH v4 21/21] Linux: Remove sysdep-cancel header Adhemerval Zanella
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20200403203201.7494-21-adhemerval.zanella@linaro.org \
--to=adhemerval.zanella@linaro.org \
--cc=libc-alpha@sourceware.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).