From: Adhemerval Zanella <adhemerval.zanella@linaro.org>
To: libc-alpha@sourceware.org,
Christian Brauner <christian.brauner@ubuntu.com>
Subject: [PATCH 6/7] riscv: Add the clone3 wrapper
Date: Wed, 28 Sep 2022 17:46:33 -0300 [thread overview]
Message-ID: <20220928204634.3036650-7-adhemerval.zanella@linaro.org> (raw)
In-Reply-To: <20220928204634.3036650-1-adhemerval.zanella@linaro.org>
It follows the internal signature:
extern int clone3 (struct clone_args *__cl_args, size_t __size,
int (*__func) (void *__arg), void *__arg);
And x86_64 semantics to return EINVAL if either cl_args or func
is NULL. The stack is 16-byte aligned prior executing func.
Checked on riscv64-linux-gnu-rv64imafdc-lp64d.
---
sysdeps/unix/sysv/linux/riscv/clone3.S | 83 ++++++++++++++++++++++++++
sysdeps/unix/sysv/linux/riscv/sysdep.h | 1 +
2 files changed, 84 insertions(+)
create mode 100644 sysdeps/unix/sysv/linux/riscv/clone3.S
diff --git a/sysdeps/unix/sysv/linux/riscv/clone3.S b/sysdeps/unix/sysv/linux/riscv/clone3.S
new file mode 100644
index 0000000000..1e6e807aa0
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/riscv/clone3.S
@@ -0,0 +1,83 @@
+/* The clone3 syscall wrapper. Linux/RISC-V version.
+ Copyright (C) 2022 Free Software Foundation, Inc.
+
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <https://www.gnu.org/licenses/>. */
+
+#include <asm/errno.h>
+#include <sys/asm.h>
+#include <sysdep.h>
+
+/* The userland implementation is:
+ int clone3 (struct clone_args *cl_args, size_t size,
+ int (*func)(void *arg), void *arg);
+
+ the kernel entry is:
+ int clone3 (struct clone_args *cl_args, size_t size);
+
+ The parameters are passed in registers from userland:
+ a0: cl_args
+ a1: size
+ a2: func
+ a3: arg */
+
+ .text
+ENTRY(__clone3)
+ /* Sanity check args. */
+ beqz a0, L(invalid) /* No NULL cl_args pointer. */
+ beqz a2, L(invalid) /* No NULL function pointer. */
+
+ /* Do the system call, the kernel expects:
+ a7: system call number
+ a0: cl_args
+ a1: size */
+ li a7, __NR_clone3
+ scall
+
+ bltz a0, L(error)
+ beqz a0, L(thread_start)
+
+ ret
+
+L(invalid):
+ li a0, -EINVAL
+L(error):
+ tail __syscall_error
+END (__clone3)
+
+ENTRY(__thread_start_clone3)
+L(thread_start):
+ /* Terminate call stack by noting ra is undefined. Use a dummy
+ .cfi_label to force starting the FDE. */
+ .cfi_label .Ldummy
+ cfi_undefined (ra)
+
+ /* Align stack to a 128-bit boundary as per RISC-V ABI. */
+ andi sp, sp, ALMASK
+
+ /* Restore the arg for user's function and call the user's
+ function. */
+ mv a1, a2 /* Function pointer. */
+ mv a0, a3 /* Argument pointer. */
+ jalr a1
+
+ /* Call exit with the function's return value. */
+ li a7, __NR_exit
+ scall
+END(__thread_start_clone3)
+
+libc_hidden_def (__clone3)
+weak_alias (__clone3, clone3)
diff --git a/sysdeps/unix/sysv/linux/riscv/sysdep.h b/sysdeps/unix/sysv/linux/riscv/sysdep.h
index 9b03b10567..57523dc7b7 100644
--- a/sysdeps/unix/sysv/linux/riscv/sysdep.h
+++ b/sysdeps/unix/sysv/linux/riscv/sysdep.h
@@ -150,6 +150,7 @@
/* RV32 does not support the gettime VDSO syscalls. */
# endif
+# define HAVE_CLONE3_WRAPPER 1
/* List of system calls which are supported as vsyscalls (for RV32 and
RV64). */
--
2.34.1
next prev parent reply other threads:[~2022-09-28 20:46 UTC|newest]
Thread overview: 8+ messages / expand[flat|nested] mbox.gz Atom feed top
2022-09-28 20:46 [PATCH 0/7] Optimize posix_spawn signal setup with clone3 Adhemerval Zanella
2022-09-28 20:46 ` [PATCH 1/7] linux: Do set signal handler if it is already SIG_DFL Adhemerval Zanella
2022-09-28 20:46 ` [PATCH 2/7] linux: Add clone3 CLONE_CLEAR_SIGHAND optimization to posix_spawn Adhemerval Zanella
2022-09-28 20:46 ` [PATCH 3/7] powerpc64le: Add the clone3 wrapper Adhemerval Zanella
2022-09-28 20:46 ` [PATCH 4/7] aarch64: " Adhemerval Zanella
2022-09-28 20:46 ` [PATCH 5/7] s390x: " Adhemerval Zanella
2022-09-28 20:46 ` Adhemerval Zanella [this message]
2022-09-28 20:46 ` [PATCH 7/7] Linux: optimize clone3 internal usage Adhemerval Zanella
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20220928204634.3036650-7-adhemerval.zanella@linaro.org \
--to=adhemerval.zanella@linaro.org \
--cc=christian.brauner@ubuntu.com \
--cc=libc-alpha@sourceware.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).