From: Adhemerval Zanella <adhemerval.zanella@linaro.org>
To: libc-alpha@sourceware.org, Christian Brauner <brauner@kernel.org>
Subject: [PATCH v2 3/9] powerpc64le: Add the clone3 wrapper
Date: Fri, 30 Sep 2022 16:26:07 -0300 [thread overview]
Message-ID: <20220930192613.3491147-4-adhemerval.zanella@linaro.org> (raw)
In-Reply-To: <20220930192613.3491147-1-adhemerval.zanella@linaro.org>
It follows the internal signature:
extern int clone3 (struct clone_args *__cl_args, size_t __size,
int (*__func) (void *__arg), void *__arg);
And x86_64 semantics to return EINVAL if either cl_args or func
is NULL. The stack is 16-byte aligned prior executing func.
Checked on powerpc64le-linux-gnu.
---
.../sysv/linux/powerpc/powerpc64/clone3.S | 145 ++++++++++++++++++
sysdeps/unix/sysv/linux/powerpc/sysdep.h | 1 +
2 files changed, 146 insertions(+)
create mode 100644 sysdeps/unix/sysv/linux/powerpc/powerpc64/clone3.S
diff --git a/sysdeps/unix/sysv/linux/powerpc/powerpc64/clone3.S b/sysdeps/unix/sysv/linux/powerpc/powerpc64/clone3.S
new file mode 100644
index 0000000000..a7461a3a42
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/powerpc/powerpc64/clone3.S
@@ -0,0 +1,145 @@
+/* The clone3 syscall wrapper. Linux/powerpc64 version.
+ Copyright (C) 2022 Free Software Foundation, Inc.
+
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <https://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+#define _ERRNO_H 1
+#include <bits/errno.h>
+
+/* The userland implementation is:
+ int clone3 (struct clone_args *cl_args, size_t size,
+ int (*func)(void *arg), void *arg);
+
+ the kernel entry is:
+ int clone3 (struct clone_args *cl_args, size_t size);
+
+ The parameters are passed in registers from userland:
+ r3: cl_args
+ r4: size
+ r5: func
+ r6: arg */
+
+ .text
+ENTRY(__clone3)
+ CALL_MCOUNT 4
+
+ /* Sanity checks args. */
+ cmpdi cr0, r3, 0
+ cmpdi cr1, r5, 0
+ cror cr0*4+eq, cr1*4+eq, cr0*4+eq
+ beq cr0,L(badargs)
+
+ /* Save some regs in the "red zone". */
+#ifdef USE_PPC_SCV
+ std r28, -24(r1)
+ cfi_offset (r28, -24)
+#endif
+ std r29, -16(r1)
+ std r30, -8(r1)
+ cfi_offset (r29, -16)
+ cfi_offset (r30, -8)
+
+ /* Save fn and args across syscall. */
+ mr r30, r5 /* Function. */
+ mr r29, r6 /* Arguments. */
+
+ /* End FDE now, because in the child the unwind info will be
+ wrong. */
+ cfi_endproc
+
+ /* Do the system call, the kernel expects:
+ r0: system call numer
+ r3: cl_args
+ r4: size */
+ li r0, SYS_ify(clone3)
+#ifdef USE_PPC_SCV
+ CHECK_SCV_SUPPORT r28 0f
+ /* This is equivalent to DO_CALL_SCV, but we cannot use the macro here
+ because it uses CFI directives and we just called cfi_endproc. */
+ mflr r9
+ std r9, FRAME_LR_SAVE(r1)
+ .machine "push"
+ .machine "power9"
+ scv 0
+ .machine "pop"
+ ld r9, FRAME_LR_SAVE(r1)
+ mtlr r9
+
+ /* When using scv, error is indicated by negative r3. */
+ cmpdi cr1, r3, 0
+ b 1f
+#endif
+0: DO_CALL_SC
+
+ /* With sc, error is indicated by cr0.SO. */
+ cmpdi cr1, r3, 0
+ crandc cr1*4+eq, cr1*4+eq, cr0*4+so
+
+1: bne- cr1,L(parent)
+
+ /* Child, load the function and arguments. */
+
+ /* Align stack. */
+ rldicr r1, r1, 0, 59
+
+ std r2, FRAME_TOC_SAVE(r1)
+ PPC64_LOAD_FUNCPTR r30
+ mr r3, r29
+ bctrl
+ ld r2, FRAME_TOC_SAVE(r1)
+
+ li r0, SYS_ify(exit)
+ DO_CALL_SC
+ /* We won't ever get here but provide a nop so that the linker
+ will insert a toc adjusting stub if necessary. */
+ nop
+
+L(badargs):
+ cfi_startproc
+ li r3, EINVAL
+ TAIL_CALL_SYSCALL_ERROR
+
+L(parent):
+ /* Check if svc is available. */
+ cmpdi cr1, r28, 0
+
+ /* Parent. Restore registers & return. */
+#ifdef USE_PPC_SCV
+ cfi_offset (r28, -24)
+ ld r28, -24(r1)
+ cfi_restore (r28)
+#endif
+ cfi_offset (r29,-16)
+ cfi_offset (r30,-8)
+ ld r29, -16(r1)
+ ld r30, -8(r1)
+ cfi_restore (r29)
+ cfi_restore (r30)
+
+#ifdef USE_PPC_SCV
+ beq cr1, 0f
+ RET_SCV
+ b 1f
+#endif
+0: RET_SC
+1: TAIL_CALL_SYSCALL_ERROR
+
+PSEUDO_END (__clone3)
+
+libc_hidden_def (__clone3)
+weak_alias (__clone3, clone3)
diff --git a/sysdeps/unix/sysv/linux/powerpc/sysdep.h b/sysdeps/unix/sysv/linux/powerpc/sysdep.h
index 4fb135aa8d..b86951207d 100644
--- a/sysdeps/unix/sysv/linux/powerpc/sysdep.h
+++ b/sysdeps/unix/sysv/linux/powerpc/sysdep.h
@@ -246,6 +246,7 @@
#if defined(__PPC64__) || defined(__powerpc64__)
#define HAVE_CLOCK_GETRES64_VSYSCALL "__kernel_clock_getres"
#define HAVE_CLOCK_GETTIME64_VSYSCALL "__kernel_clock_gettime"
+#define HAVE_CLONE3_WRAPPER 1
#else
#define HAVE_CLOCK_GETRES_VSYSCALL "__kernel_clock_getres"
#define HAVE_CLOCK_GETTIME_VSYSCALL "__kernel_clock_gettime"
--
2.34.1
next prev parent reply other threads:[~2022-09-30 19:26 UTC|newest]
Thread overview: 28+ messages / expand[flat|nested] mbox.gz Atom feed top
2022-09-30 19:26 [PATCH v2 0/9] Optimize posix_spawn signal setup with clone3 Adhemerval Zanella
2022-09-30 19:26 ` [PATCH v2 1/9] linux: Do not reset signal handler in posix_spawn if it is already SIG_DFL Adhemerval Zanella
2023-01-11 21:06 ` Carlos O'Donell
2022-09-30 19:26 ` [PATCH v2 2/9] linux: Add clone3 CLONE_CLEAR_SIGHAND optimization to posix_spawn Adhemerval Zanella
2023-01-11 21:06 ` Carlos O'Donell
2022-09-30 19:26 ` Adhemerval Zanella [this message]
2022-09-30 19:26 ` [PATCH v2 4/9] aarch64: Add the clone3 wrapper Adhemerval Zanella
2022-11-02 12:12 ` Szabolcs Nagy
2022-11-03 13:15 ` Adhemerval Zanella Netto
2022-11-03 14:01 ` Szabolcs Nagy
2022-11-03 16:22 ` Adhemerval Zanella Netto
2022-11-03 16:31 ` Szabolcs Nagy
2022-11-03 16:39 ` Adhemerval Zanella Netto
2022-11-03 16:52 ` Szabolcs Nagy
2022-11-03 16:55 ` Adhemerval Zanella Netto
2022-11-03 20:55 ` H.J. Lu
2022-11-03 21:28 ` Adhemerval Zanella Netto
2022-11-03 21:22 ` Adhemerval Zanella Netto
2022-11-03 21:58 ` H.J. Lu
2022-11-04 12:32 ` Adhemerval Zanella Netto
2022-09-30 19:26 ` [PATCH v2 5/9] s390x: " Adhemerval Zanella
2022-09-30 19:26 ` [PATCH v2 6/9] riscv: " Adhemerval Zanella
2022-09-30 19:26 ` [PATCH v2 7/9] arm: " Adhemerval Zanella
2022-09-30 19:26 ` [PATCH v2 8/9] mips: " Adhemerval Zanella
2022-09-30 19:26 ` [PATCH v2 9/9] Linux: optimize clone3 internal usage Adhemerval Zanella
2023-01-11 21:12 ` Carlos O'Donell
2022-10-27 16:48 ` [PATCH v2 0/9] Optimize posix_spawn signal setup with clone3 Adhemerval Zanella Netto
2023-01-11 21:11 ` Carlos O'Donell
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20220930192613.3491147-4-adhemerval.zanella@linaro.org \
--to=adhemerval.zanella@linaro.org \
--cc=brauner@kernel.org \
--cc=libc-alpha@sourceware.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).