From: Adhemerval Zanella <adhemerval.zanella@linaro.org>
To: libc-alpha@sourceware.org, Szabolcs Nagy <szabolcs.nagy@arm.com>,
"H . J . Lu" <hjl.tools@gmail.com>
Cc: Christian Brauner <brauner@kernel.org>
Subject: [PATCH v2 07/11] s390x: Add the clone3 wrapper
Date: Fri, 4 Nov 2022 16:01:08 -0300 [thread overview]
Message-ID: <20221104190112.2566409-8-adhemerval.zanella@linaro.org> (raw)
In-Reply-To: <20221104190112.2566409-1-adhemerval.zanella@linaro.org>
It follows the internal signature:
extern int clone3 (struct clone_args *__cl_args, size_t __size,
int (*__func) (void *__arg), void *__arg);
Checked on s390x-linux-gnu.
---
sysdeps/unix/sysv/linux/s390/s390-64/clone3.S | 81 +++++++++++++++++++
sysdeps/unix/sysv/linux/s390/sysdep.h | 1 +
2 files changed, 82 insertions(+)
create mode 100644 sysdeps/unix/sysv/linux/s390/s390-64/clone3.S
diff --git a/sysdeps/unix/sysv/linux/s390/s390-64/clone3.S b/sysdeps/unix/sysv/linux/s390/s390-64/clone3.S
new file mode 100644
index 0000000000..873d9a74b7
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/s390/s390-64/clone3.S
@@ -0,0 +1,81 @@
+/* The clone3 syscall wrapper. Linux/s390x version.
+ Copyright (C) 2022 Free Software Foundation, Inc.
+
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <https://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+#define _ERRNO_H 1
+#include <bits/errno.h>
+
+/* The userland implementation is:
+ int clone3 (struct clone_args *cl_args, size_t size,
+ int (*func)(void *arg), void *arg);
+
+ the kernel entry is:
+ int clone3 (struct clone_args *cl_args, size_t size);
+
+ The parameters are passed in registers from userland:
+ r2: cl_args
+ r3: size
+ r4: func
+ r5: arg */
+
+ .text
+ENTRY(__clone3)
+ stg %r6, 48(%r15)
+
+ /* Sanity check args. */
+ ltgr %r2, %r2
+ je error
+ ltgr %r6, %r4
+ je error
+
+ /* Do the system call, the kernel expects:
+ r1: system call number
+ r2: cl_args
+ r3: size */
+ lghi %r1, SYS_ify(clone3)
+ svc 0
+ ltgr %r2,%r2 /* check return code */
+ jz thread_start
+ lg %r6, 48(%r15)
+ jgm SYSCALL_ERROR_LABEL
+ br %r14
+error:
+ lghi %r2,-EINVAL
+ jg SYSCALL_ERROR_LABEL
+PSEUDO_END (__clone3)
+
+ .align 4
+ .type thread_start, %function
+thread_start:
+ cfi_startproc
+ /* Mark r14 as undefined in order to stop unwinding here. */
+ cfi_undefined (r14)
+
+ /* func is in gpr 6, arg in gpr 5. */
+ lgr %r2, %r5
+ aghi %r15, -160
+ xc 0(8,%r15),0(%r15)
+ basr %r14, %r6
+
+ DO_CALL (exit, 1)
+ cfi_endproc
+ .size thread_start, .-thread_start
+
+libc_hidden_def (__clone3)
+weak_alias (__clone3, clone3)
diff --git a/sysdeps/unix/sysv/linux/s390/sysdep.h b/sysdeps/unix/sysv/linux/s390/sysdep.h
index 930d7efe03..366c797ef1 100644
--- a/sysdeps/unix/sysv/linux/s390/sysdep.h
+++ b/sysdeps/unix/sysv/linux/s390/sysdep.h
@@ -72,6 +72,7 @@
#ifdef __s390x__
#define HAVE_CLOCK_GETRES64_VSYSCALL "__kernel_clock_getres"
#define HAVE_CLOCK_GETTIME64_VSYSCALL "__kernel_clock_gettime"
+#define HAVE_CLONE3_WRAPPER 1
#else
#define HAVE_CLOCK_GETRES_VSYSCALL "__kernel_clock_getres"
#define HAVE_CLOCK_GETTIME_VSYSCALL "__kernel_clock_gettime"
--
2.34.1
next prev parent reply other threads:[~2022-11-04 19:01 UTC|newest]
Thread overview: 22+ messages / expand[flat|nested] mbox.gz Atom feed top
2022-11-04 19:01 [PATCH v2 00/11] Optimize posix_spawn signal setup with clone3 Adhemerval Zanella
2022-11-04 19:01 ` [PATCH v2 01/11] linux: Do not reset signal handler in posix_spawn if it is already SIG_DFL Adhemerval Zanella
2023-01-11 21:27 ` Carlos O'Donell
2022-11-04 19:01 ` [PATCH v2 02/11] linux: Extend internal clone3 documentation Adhemerval Zanella
2022-11-07 16:40 ` Szabolcs Nagy
2023-01-11 21:35 ` Carlos O'Donell
2022-11-04 19:01 ` [PATCH v2 03/11] Linux: Do not align the stack for __clone3 Adhemerval Zanella
2023-01-11 21:43 ` Carlos O'Donell
2022-11-04 19:01 ` [PATCH v2 04/11] linux: Add clone3 CLONE_CLEAR_SIGHAND optimization to posix_spawn Adhemerval Zanella
2023-01-11 21:44 ` Carlos O'Donell
2022-11-04 19:01 ` [PATCH v2 05/11] powerpc64: Add the clone3 wrapper Adhemerval Zanella
2022-11-28 16:38 ` Paul E Murphy
2022-11-29 20:43 ` Adhemerval Zanella Netto
2022-11-04 19:01 ` [PATCH v2 06/11] aarch64: " Adhemerval Zanella
2022-11-07 16:14 ` Szabolcs Nagy
2022-11-04 19:01 ` Adhemerval Zanella [this message]
2022-11-04 19:01 ` [PATCH v2 08/11] riscv: " Adhemerval Zanella
2022-11-04 19:01 ` [PATCH v2 09/11] arm: " Adhemerval Zanella
2022-11-04 19:01 ` [PATCH v2 10/11] mips: " Adhemerval Zanella
2022-11-04 19:01 ` [PATCH v2 11/11] Linux: optimize clone3 internal usage Adhemerval Zanella
2023-01-11 21:45 ` Carlos O'Donell
2023-01-11 21:24 ` [PATCH v2 00/11] Optimize posix_spawn signal setup with clone3 Carlos O'Donell
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20221104190112.2566409-8-adhemerval.zanella@linaro.org \
--to=adhemerval.zanella@linaro.org \
--cc=brauner@kernel.org \
--cc=hjl.tools@gmail.com \
--cc=libc-alpha@sourceware.org \
--cc=szabolcs.nagy@arm.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).