From: Sergey Bugaev <bugaevc@gmail.com>
To: libc-alpha@sourceware.org
Cc: bug-hurd@gnu.org, Samuel Thibault <samuel.thibault@gnu.org>
Subject: [PATCH v3 2/6] hurd: Implement longjmp for x86_64
Date: Sat, 29 Apr 2023 23:18:18 +0300 [thread overview]
Message-ID: <20230429201822.2605207-3-bugaevc@gmail.com> (raw)
In-Reply-To: <20230429201822.2605207-1-bugaevc@gmail.com>
Checked on x86_64-gnu.
Signed-off-by: Sergey Bugaev <bugaevc@gmail.com>
---
I have checked that setjmp/longjmp actually works sucessfully, with both
__longjmp and ____longjmp_chk. I have not been able to check w/ sigaltstack
because we don't yet have the proc server and signals.
Changes since v1:
- drop the separate non-PIC version, we can always use %rip-relative access
on x86_64, and that's what the compiler generates anyway even with -fno-pic;
- use "cmpb $0, __libc_tls_initialized(%rip)" over
"movb __libc_tls_initialized(%rip), %r10b; testb %r10b, %r10b" -- the former
is what the compiler generates, so better be consistent.
sysdeps/mach/hurd/x86_64/____longjmp_chk.S | 118 +++++++++++++++++++++
sysdeps/mach/hurd/x86_64/__longjmp.S | 96 +++++++++++++++++
2 files changed, 214 insertions(+)
create mode 100644 sysdeps/mach/hurd/x86_64/____longjmp_chk.S
create mode 100644 sysdeps/mach/hurd/x86_64/__longjmp.S
diff --git a/sysdeps/mach/hurd/x86_64/____longjmp_chk.S b/sysdeps/mach/hurd/x86_64/____longjmp_chk.S
new file mode 100644
index 00000000..935b8575
--- /dev/null
+++ b/sysdeps/mach/hurd/x86_64/____longjmp_chk.S
@@ -0,0 +1,118 @@
+/* Checked longjmp support. x86_64 Hurd version.
+ Copyright (C) 2001-2023 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <https://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+#include <pointer_guard.h>
+#include <jmpbuf-offsets.h>
+#include <asm-syntax.h>
+#include <tcb-offsets.h>
+#include <jmp_buf-ssp.h>
+#include <signal-defines.h>
+
+#define SS_ONSTACK 1
+
+/* Don't restore shadow stack register if shadow stack isn't enabled. */
+#if !SHSTK_ENABLED
+# undef SHADOW_STACK_POINTER_OFFSET
+#endif
+
+ .section .rodata.str1.1,"aMS",@progbits,1
+ .type longjmp_msg,@object
+longjmp_msg:
+ .string "longjmp causes uninitialized stack frame"
+ .size longjmp_msg, .-longjmp_msg
+
+
+# define CALL_FAIL sub $8, %RSP_LP; \
+ cfi_remember_state; \
+ cfi_def_cfa_offset(16); \
+ lea longjmp_msg(%rip), %RDI_LP; \
+ call HIDDEN_JUMPTARGET(__fortify_fail); \
+ nop; \
+ cfi_restore_state
+
+/* Jump to the position specified by ENV, causing the
+ setjmp call there to return VAL, or 1 if VAL is 0.
+ void __longjmp (__jmp_buf env, int val). */
+ .text
+ENTRY(____longjmp_chk)
+ /* Restore registers. */
+ mov (JB_RSP*8)(%rdi), %R8_LP
+ mov (JB_RBP*8)(%rdi),%R9_LP
+ mov (JB_PC*8)(%rdi), %RDX_LP
+#ifdef PTR_DEMANGLE
+ PTR_DEMANGLE (%R8_LP)
+ PTR_DEMANGLE (%R9_LP)
+ PTR_DEMANGLE (%RDX_LP)
+#endif
+
+#if !defined (SHARED) || IS_IN (rtld)
+ cmpb $0, __libc_tls_initialized(%rip)
+ jz .Lok /* TLS not initialized yet */
+#endif
+
+ movq %fs:SIGSTATE_OFFSET, %R10_LP
+ testq %R10_LP, %R10_LP
+ jz .Lok /* sigstate not initialized yet */
+
+ testl $SS_ONSTACK, (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_FLAGS__OFFSET)(%R10_LP)
+ jnz .Lonstack
+
+ /* We were on the main stack. Jumping to a higher-address
+ frame is always allowed, otherwise it's not allowed. */
+ cmp %R8_LP, %RSP_LP
+ jbe .Lok
+
+.Lfail: CALL_FAIL
+
+.Lonstack:
+ cmpq (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_SP__OFFSET)(%R10_LP), %R8_LP
+ jb .Loks /* Jumping below the altstack, switch */
+
+ movq (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_SP__OFFSET)(%R10_LP), %R11_LP
+ addq (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_SIZE__OFFSET)(%R10_LP), %R11_LP
+ cmpq %R11_LP, %R8_LP
+ jb .Lok /* Jumping inside the altstack, do not switch */
+
+ /* Jumping above the altstack, switch */
+
+.Loks:
+ andl $~(SS_ONSTACK), (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_FLAGS__OFFSET)(%R10_LP)
+
+.Lok:
+ /* We add unwind information for the target here. */
+ cfi_def_cfa(%rdi, 0)
+ cfi_register(%rsp,%r8)
+ cfi_register(%rbp,%r9)
+ cfi_register(%rip,%rdx)
+ cfi_offset(%rbx,JB_RBX*8)
+ cfi_offset(%r12,JB_R12*8)
+ cfi_offset(%r13,JB_R13*8)
+ cfi_offset(%r14,JB_R14*8)
+ cfi_offset(%r15,JB_R15*8)
+ movq (JB_RBX*8)(%rdi), %rbx
+ movq (JB_R12*8)(%rdi), %r12
+ movq (JB_R13*8)(%rdi), %r13
+ movq (JB_R14*8)(%rdi), %r14
+ movq (JB_R15*8)(%rdi), %r15
+ /* Set return value for setjmp. */
+ movl %esi, %eax
+ mov %R8_LP, %RSP_LP
+ movq %r9,%rbp
+ jmpq *%rdx
+END (____longjmp_chk)
diff --git a/sysdeps/mach/hurd/x86_64/__longjmp.S b/sysdeps/mach/hurd/x86_64/__longjmp.S
new file mode 100644
index 00000000..389c1d16
--- /dev/null
+++ b/sysdeps/mach/hurd/x86_64/__longjmp.S
@@ -0,0 +1,96 @@
+/* longjmp support. x86_64/Hurd version.
+ Copyright (C) 2001-2023 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <https://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+#include <pointer_guard.h>
+#include <jmpbuf-offsets.h>
+#include <asm-syntax.h>
+#include <tcb-offsets.h>
+#include <jmp_buf-ssp.h>
+#include <signal-defines.h>
+
+#define SS_ONSTACK 1
+
+/* Don't restore shadow stack register if shadow stack isn't enabled. */
+#if !SHSTK_ENABLED
+# undef SHADOW_STACK_POINTER_OFFSET
+#endif
+
+/* Jump to the position specified by ENV, causing the
+ setjmp call there to return VAL, or 1 if VAL is 0.
+ void __longjmp (__jmp_buf env, int val). */
+ .text
+ENTRY(__longjmp)
+ /* Restore registers. */
+ mov (JB_RSP*8)(%rdi), %R8_LP
+ mov (JB_RBP*8)(%rdi),%R9_LP
+ mov (JB_PC*8)(%rdi), %RDX_LP
+#ifdef PTR_DEMANGLE
+ PTR_DEMANGLE (%R8_LP)
+ PTR_DEMANGLE (%R9_LP)
+ PTR_DEMANGLE (%RDX_LP)
+#endif
+
+#if !defined (SHARED) || IS_IN (rtld)
+ cmpb $0, __libc_tls_initialized(%rip)
+ jz .Lok /* TLS not initialized yet */
+#endif
+
+ movq %fs:SIGSTATE_OFFSET, %R10_LP
+ testq %R10_LP, %R10_LP
+ jz .Lok /* sigstate not initialized yet */
+
+ testl $SS_ONSTACK, (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_FLAGS__OFFSET)(%R10_LP)
+ jz .Lok
+
+.Lonstack:
+ cmpq (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_SP__OFFSET)(%R10_LP), %R8_LP
+ jb .Loks /* Jumping below the altstack, switch */
+
+ movq (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_SP__OFFSET)(%R10_LP), %R11_LP
+ addq (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_SIZE__OFFSET)(%R10_LP), %R11_LP
+ cmpq %R11_LP, %R8_LP
+ jb .Lok /* Jumping inside the altstack, do not switch */
+
+ /* Jumping above the altstack, switch */
+
+.Loks:
+ andl $~(SS_ONSTACK), (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_FLAGS__OFFSET)(%R10_LP)
+
+.Lok:
+ /* We add unwind information for the target here. */
+ cfi_def_cfa(%rdi, 0)
+ cfi_register(%rsp,%r8)
+ cfi_register(%rbp,%r9)
+ cfi_register(%rip,%rdx)
+ cfi_offset(%rbx,JB_RBX*8)
+ cfi_offset(%r12,JB_R12*8)
+ cfi_offset(%r13,JB_R13*8)
+ cfi_offset(%r14,JB_R14*8)
+ cfi_offset(%r15,JB_R15*8)
+ movq (JB_RBX*8)(%rdi), %rbx
+ movq (JB_R12*8)(%rdi), %r12
+ movq (JB_R13*8)(%rdi), %r13
+ movq (JB_R14*8)(%rdi), %r14
+ movq (JB_R15*8)(%rdi), %r15
+ /* Set return value for setjmp. */
+ movl %esi, %eax
+ mov %R8_LP, %RSP_LP
+ movq %r9,%rbp
+ jmpq *%rdx
+END (__longjmp)
--
2.40.1
next prev parent reply other threads:[~2023-04-29 20:18 UTC|newest]
Thread overview: 20+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-04-29 20:18 [PATCH v3 0/6] The remaining x86_64-gnu patches Sergey Bugaev
2023-04-29 20:18 ` [PATCH v3 1/6] hurd: Implement sigreturn for x86_64 Sergey Bugaev
2023-04-30 23:06 ` Samuel Thibault
2023-04-29 20:18 ` Sergey Bugaev [this message]
2023-04-30 23:16 ` [PATCH v3 2/6] hurd: Implement longjmp " Samuel Thibault
2023-04-29 20:18 ` [RFC PATCH v3 3/6] hurd: Replace reply port with a dead name on failed interruption Sergey Bugaev
2023-05-01 1:20 ` Samuel Thibault
2023-04-29 20:18 ` [PATCH v3 4/6] hurd: Add expected abilist files for x86_64 Sergey Bugaev
2023-04-30 23:18 ` Samuel Thibault
2023-05-01 10:20 ` Samuel Thibault
2023-05-01 17:33 ` Sergey Bugaev
2023-05-01 17:43 ` Samuel Thibault
2023-04-29 20:18 ` [RFC PATCH v3 5/6] hurd: Make it possible to call memcpy very early Sergey Bugaev
2023-04-30 23:21 ` Samuel Thibault
2023-04-29 20:18 ` [DO NOT PUSH PATCH v3 6/6] TMP hurd: Lower BRK_START Sergey Bugaev
2023-05-02 14:03 ` [PATCH v3 0/6] The remaining x86_64-gnu patches Joseph Myers
2023-05-02 14:16 ` Sergey Bugaev
2023-05-02 18:27 ` Joseph Myers
2023-05-02 15:17 ` Samuel Thibault
2023-05-02 18:24 ` Joseph Myers
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20230429201822.2605207-3-bugaevc@gmail.com \
--to=bugaevc@gmail.com \
--cc=bug-hurd@gnu.org \
--cc=libc-alpha@sourceware.org \
--cc=samuel.thibault@gnu.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).