From: Adhemerval Zanella <adhemerval.zanella@linaro.org>
To: libc-alpha@sourceware.org, Florian Weimer <fweimer@redhat.com>
Subject: [PATCH v9 2/6] mips: Add the clone3 wrapper
Date: Thu, 24 Aug 2023 13:42:15 -0300 [thread overview]
Message-ID: <20230824164219.391263-3-adhemerval.zanella@linaro.org> (raw)
In-Reply-To: <20230824164219.391263-1-adhemerval.zanella@linaro.org>
It follows the internal signature:
extern int clone3 (struct clone_args *__cl_args, size_t __size,
int (*__func) (void *__arg), void *__arg);
Checked on mips64el-linux-gnueabihf, mips64el-n32-linux-gnu, and
mipsel-linux-gnu.
---
sysdeps/unix/sysv/linux/mips/clone3.S | 139 ++++++++++++++++++++++++++
sysdeps/unix/sysv/linux/mips/sysdep.h | 2 +
2 files changed, 141 insertions(+)
create mode 100644 sysdeps/unix/sysv/linux/mips/clone3.S
diff --git a/sysdeps/unix/sysv/linux/mips/clone3.S b/sysdeps/unix/sysv/linux/mips/clone3.S
new file mode 100644
index 0000000000..1d16bfcef6
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/mips/clone3.S
@@ -0,0 +1,139 @@
+/* The clone3 syscall wrapper. Linux/mips version.
+ Copyright (C) 2023 Free Software Foundation, Inc.
+
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <https://www.gnu.org/licenses/>. */
+
+#include <sys/asm.h>
+#include <sysdep.h>
+#define _ERRNO_H 1
+#include <bits/errno.h>
+
+/* The userland implementation is:
+ int clone3 (struct clone_args *cl_args, size_t size,
+ int (*func)(void *arg), void *arg);
+
+ the kernel entry is:
+ int clone3 (struct clone_args *cl_args, size_t size);
+
+ The parameters are passed in registers from userland:
+ a0/$4: cl_args
+ a1/$5: size
+ a2/$6: func
+ a3/$7: arg */
+
+ .text
+ .set nomips16
+#if _MIPS_SIM == _ABIO32
+# define EXTRA_LOCALS 1
+#else
+# define EXTRA_LOCALS 0
+#endif
+#define FRAMESZ ((NARGSAVE*SZREG)+ALSZ)&ALMASK
+GPOFF= FRAMESZ-(1*SZREG)
+NESTED(__clone3, SZREG, sp)
+#ifdef __PIC__
+ SETUP_GP
+#endif
+#if FRAMESZ
+ PTR_SUBU sp, FRAMESZ
+ cfi_adjust_cfa_offset (FRAMESZ)
+#endif
+ SETUP_GP64_STACK (GPOFF, __clone3)
+#ifdef __PIC__
+ SAVE_GP (GPOFF)
+#endif
+#ifdef PROF
+ .set noat
+ move $1,ra
+ jal _mcount
+ .set at
+#endif
+
+ /* Sanity check args. */
+ li v0, EINVAL
+ beqz a0, L(error) /* No NULL cl_args pointer. */
+ beqz a2, L(error) /* No NULL function pointer. */
+
+ move $8, a3 /* a3 is set to 0/1 for syscall success/error
+ while a4/$8 is returned unmodified. */
+
+ /* Do the system call, the kernel expects:
+ v0: system call number
+ a0: cl_args
+ a1: size */
+ li v0, __NR_clone3
+ cfi_endproc
+ syscall
+
+ bnez a3, L(error)
+ beqz v0, L(thread_start_clone3)
+
+ /* Successful return from the parent */
+ cfi_startproc
+#if FRAMESZ
+ cfi_adjust_cfa_offset (FRAMESZ)
+#endif
+ SETUP_GP64_STACK_CFI (GPOFF)
+ cfi_remember_state
+ RESTORE_GP64_STACK
+#if FRAMESZ
+ PTR_ADDU sp, FRAMESZ
+ cfi_adjust_cfa_offset (-FRAMESZ)
+#endif
+ ret
+
+L(error):
+ cfi_restore_state
+#ifdef __PIC__
+ PTR_LA t9, __syscall_error
+ RESTORE_GP64_STACK
+ PTR_ADDU sp, FRAMESZ
+ cfi_adjust_cfa_offset (-FRAMESZ)
+ jr t9
+#else
+ RESTORE_GP64_STACK
+ PTR_ADDU sp, FRAMESZ
+ cfi_adjust_cfa_offset (-FRAMESZ)
+ j __syscall_error
+#endif
+END (__clone3)
+
+/* Load up the arguments to the function. Put this block of code in
+ its own function so that we can terminate the stack trace with our
+ debug info. */
+
+ENTRY(__thread_start_clone3)
+L(thread_start_clone3):
+ cfi_undefined ($31)
+ /* cp is already loaded. */
+ SAVE_GP (GPOFF)
+ /* The stackframe has been created on entry of clone3. */
+
+ /* Restore the arg for user's function. */
+ move t9, a2 /* Function pointer. */
+ move a0, $8 /* Argument pointer. */
+
+ /* Call the user's function. */
+ jal t9
+
+ move a0, v0
+ li v0, __NR_exit
+ syscall
+END(__thread_start_clone3)
+
+libc_hidden_def (__clone3)
+weak_alias (__clone3, clone3)
diff --git a/sysdeps/unix/sysv/linux/mips/sysdep.h b/sysdeps/unix/sysv/linux/mips/sysdep.h
index ff84a91b31..673aa08b57 100644
--- a/sysdeps/unix/sysv/linux/mips/sysdep.h
+++ b/sysdeps/unix/sysv/linux/mips/sysdep.h
@@ -28,3 +28,5 @@
#endif
#define HAVE_GETTIMEOFDAY_VSYSCALL "__vdso_gettimeofday"
#define HAVE_CLOCK_GETRES_VSYSCALL "__vdso_clock_getres"
+
+#define HAVE_CLONE3_WRAPPER 1
--
2.34.1
next prev parent reply other threads:[~2023-08-24 16:42 UTC|newest]
Thread overview: 13+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-08-24 16:42 [PATCH v9 0/6] Add pidfd and cgroupv2 support for process creation Adhemerval Zanella
2023-08-24 16:42 ` [PATCH v9 1/6] arm: Add the clone3 wrapper Adhemerval Zanella
2023-09-04 12:04 ` Florian Weimer
2023-09-05 13:14 ` Adhemerval Zanella Netto
2023-08-24 16:42 ` Adhemerval Zanella [this message]
2023-09-04 12:04 ` [PATCH v9 2/6] mips: " Florian Weimer
2023-09-05 13:15 ` Adhemerval Zanella Netto
2023-08-24 16:42 ` [PATCH v9 3/6] linux: Define __ASSUME_CLONE3 to 0 for alpha, ia64, nios2, sh, and sparc Adhemerval Zanella
2023-08-24 16:42 ` [PATCH v9 4/6] linux: Add posix_spawnattr_{get,set}cgroup_np (BZ 26731) Adhemerval Zanella
2023-08-24 16:42 ` [PATCH v9 5/6] posix: Add pidfd_spawn and pidfd_spawnp (BZ 30349) Adhemerval Zanella
2023-09-04 12:53 ` Florian Weimer
2023-08-24 16:42 ` [PATCH v9 6/6] linux: Add pidfd_getpid Adhemerval Zanella
2023-08-28 12:42 ` [PATCH v9 0/6] Add pidfd and cgroupv2 support for process creation Luca Boccassi
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20230824164219.391263-3-adhemerval.zanella@linaro.org \
--to=adhemerval.zanella@linaro.org \
--cc=fweimer@redhat.com \
--cc=libc-alpha@sourceware.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).