From: Noah Goldstein <goldstein.w.n@gmail.com>
To: "H.J. Lu" <hjl.tools@gmail.com>
Cc: GNU C Library <libc-alpha@sourceware.org>,
Florian Weimer <fweimer@redhat.com>
Subject: Re: [PATCH v5 4/5] x86-64: Add the clone3 wrapper
Date: Thu, 20 May 2021 14:39:37 -0400 [thread overview]
Message-ID: <CAFUsyfKjyhqshBVTJqVG=JWi8Ew8vcfmYGX1se+VuXWULL7OtQ@mail.gmail.com> (raw)
In-Reply-To: <CAFUsyfLvzwLw1_agKdCaADmCNsr8PW75dXvrsbOHgwLQYaSC3w@mail.gmail.com>
On Thu, May 20, 2021 at 2:35 PM Noah Goldstein <goldstein.w.n@gmail.com> wrote:
>
> On Sat, May 15, 2021 at 9:23 AM H.J. Lu via Libc-alpha
> <libc-alpha@sourceware.org> wrote:
> >
> > extern int clone3 (struct clone_args *__cl_args,
> > int (*__func) (void *__arg), void *__arg);
> > ---
> > sysdeps/unix/sysv/linux/x86_64/clone3.S | 92 +++++++++++++++++++++++++
> > sysdeps/unix/sysv/linux/x86_64/sysdep.h | 2 +
> > 2 files changed, 94 insertions(+)
> > create mode 100644 sysdeps/unix/sysv/linux/x86_64/clone3.S
> >
> > diff --git a/sysdeps/unix/sysv/linux/x86_64/clone3.S b/sysdeps/unix/sysv/linux/x86_64/clone3.S
> > new file mode 100644
> > index 0000000000..f7d4036a6a
> > --- /dev/null
> > +++ b/sysdeps/unix/sysv/linux/x86_64/clone3.S
> > @@ -0,0 +1,92 @@
> > +/* The clone3 syscall wrapper. Linux/x86-64 version.
> > + Copyright (C) 2021 Free Software Foundation, Inc.
> > + This file is part of the GNU C Library.
> > +
> > + The GNU C Library is free software; you can redistribute it and/or
> > + modify it under the terms of the GNU Lesser General Public
> > + License as published by the Free Software Foundation; either
> > + version 2.1 of the License, or (at your option) any later version.
> > +
> > + The GNU C Library is distributed in the hope that it will be useful,
> > + but WITHOUT ANY WARRANTY; without even the implied warranty of
> > + MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
> > + Lesser General Public License for more details.
> > +
> > + You should have received a copy of the GNU Lesser General Public
> > + License along with the GNU C Library; if not, see
> > + <https://www.gnu.org/licenses/>. */
> > +
> > +/* clone3() is even more special than fork() as it mucks with stacks
> > + and invokes a function in the right context after its all over. */
> > +
> > +#include <sysdep.h>
> > +#include <clone-offsets.h>
> > +
> > +/* The userland implementation is:
> > + int clone3 (struct clone_args *cl_args, int (*func)(void *arg),
> > + void *arg);
> > + the kernel entry is:
> > + int clone3 (struct clone_args *cl_args, size_t size);
> > +
> > + The parameters are passed in registers from userland:
> > + rdi: cl_args
> > + rsi: func
> > + rdx: arg
> > +
> > + The kernel expects:
> > + rax: system call number
> > + rdi: cl_args
> > + rsi: size */
> > +
> > + .text
> > +ENTRY (__clone3)
> > + /* Sanity check arguments. */
> > + movq $-EINVAL, %rax
>
> Can this be movl?
>
> > + testq %rdi, %rdi /* No NULL cl_args pointer. */
> > + jz SYSCALL_ERROR_LABEL
> > + testq %rsi, %rsi /* No NULL function pointer. */
> > + jz SYSCALL_ERROR_LABEL
> > +
> > + /* Save the function pointer in R8 which is preserved by the
> > + syscall. */
> > + movq %rsi, %r8
> > +
> > + /* Put sizeof (struct clone_args) in ESI. */
> > + movl $CLONE_ARGS_SIZE , %esi
> > +
> > + /* Do the system call. */
> > + movl $SYS_ify(clone3), %eax
> > +
> > + /* End FDE now, because in the child the unwind info will be
> > + wrong. */
> > + cfi_endproc
> > + syscall
> > +
> > + test %RAX_LP, %RAX_LP
> > + jl SYSCALL_ERROR_LABEL
> > + jz L(thread_start)
> > +
>
> Is expectation to go to L(thread_start)? If so
> think jnz L(ret) and fallthrough is probably
> better.
Or better take the error check branch off
the critical path with jnz L(error_or_ret) then jl
in L(error_or_ret)
>
> > + ret
> > +
> > +L(thread_start):
> > + cfi_startproc
> > + /* Clearing frame pointer is insufficient, use CFI. */
> > + cfi_undefined (rip)
> > + /* Clear the frame pointer. The ABI suggests this be done, to mark
> > + the outermost frame obviously. */
> > + xorl %ebp, %ebp
> > +
> > + /* Set up arguments for the function call. */
> > + movq %rdx, %rdi /* Argument. */
> > + call *%r8 /* Call function. */
> > + /* Call exit with return value from function call. */
> > + movq %rax, %rdi
> > + movl $SYS_ify(exit), %eax
> > + syscall
> > + cfi_endproc
> > +
> > + cfi_startproc
> > +PSEUDO_END (__clone3)
> > +
> > +libc_hidden_def (__clone3)
> > +weak_alias (__clone3, clone3)
> > diff --git a/sysdeps/unix/sysv/linux/x86_64/sysdep.h b/sysdeps/unix/sysv/linux/x86_64/sysdep.h
> > index dbad2c788a..f26ffc68ae 100644
> > --- a/sysdeps/unix/sysv/linux/x86_64/sysdep.h
> > +++ b/sysdeps/unix/sysv/linux/x86_64/sysdep.h
> > @@ -377,6 +377,8 @@
> > # define HAVE_GETCPU_VSYSCALL "__vdso_getcpu"
> > # define HAVE_CLOCK_GETRES64_VSYSCALL "__vdso_clock_getres"
> >
> > +# define HAVE_CLONE3_WAPPER 1
> > +
> > # define SINGLE_THREAD_BY_GLOBAL 1
> >
> > #endif /* __ASSEMBLER__ */
> > --
> > 2.31.1
> >
next prev parent reply other threads:[~2021-05-20 18:39 UTC|newest]
Thread overview: 19+ messages / expand[flat|nested] mbox.gz Atom feed top
2021-05-15 12:34 [PATCH v5 0/5] Add an internal wrapper for clone, clone2 and clone3 H.J. Lu
2021-05-15 12:34 ` [PATCH v5 1/5] " H.J. Lu
2021-05-20 14:46 ` Florian Weimer
2021-05-22 1:14 ` H.J. Lu
2021-05-15 12:34 ` [PATCH v5 2/5] nptl: Always pass stack size to create_thread H.J. Lu
2021-05-20 14:26 ` Florian Weimer
2021-05-15 12:34 ` [PATCH v5 3/5] GLIBC_PRIVATE: Export __clone_internal H.J. Lu
2021-05-17 13:54 ` Andreas Schwab
2021-05-20 14:24 ` Florian Weimer
2021-05-22 1:55 ` H.J. Lu
2021-05-15 12:34 ` [PATCH v5 4/5] x86-64: Add the clone3 wrapper H.J. Lu
2021-05-20 14:53 ` Florian Weimer
2021-05-22 1:38 ` H.J. Lu
2021-05-20 18:35 ` Noah Goldstein
2021-05-20 18:39 ` Noah Goldstein [this message]
2021-05-22 1:52 ` H.J. Lu
2021-05-15 12:34 ` [PATCH v5 5/5] Add tests for __clone_internal H.J. Lu
2021-05-20 15:08 ` Florian Weimer
2021-05-22 1:54 ` H.J. Lu
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to='CAFUsyfKjyhqshBVTJqVG=JWi8Ew8vcfmYGX1se+VuXWULL7OtQ@mail.gmail.com' \
--to=goldstein.w.n@gmail.com \
--cc=fweimer@redhat.com \
--cc=hjl.tools@gmail.com \
--cc=libc-alpha@sourceware.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).