From: Adhemerval Zanella Netto <adhemerval.zanella@linaro.org>
To: libc-alpha@sourceware.org
Subject: Re: [PATCH 5/5] mips: Add the clone3 wrapper
Date: Thu, 25 May 2023 14:36:43 -0300 [thread overview]
Message-ID: <f27d3bb6-a502-d3cc-a00e-d4c31c22abe5@linaro.org> (raw)
In-Reply-To: <20230203171237.1220878-6-adhemerval.zanella@linaro.org>
Ping.
On 03/02/23 14:12, Adhemerval Zanella wrote:
> It follows the internal signature:
>
> extern int clone3 (struct clone_args *__cl_args, size_t __size,
> int (*__func) (void *__arg), void *__arg);
>
> Checked on mips64el-linux-gnueabihf and mipsel-linux-gnu.
> ---
> sysdeps/unix/sysv/linux/mips/clone3.S | 139 ++++++++++++++++++++++++++
> sysdeps/unix/sysv/linux/mips/sysdep.h | 2 +
> 2 files changed, 141 insertions(+)
> create mode 100644 sysdeps/unix/sysv/linux/mips/clone3.S
>
> diff --git a/sysdeps/unix/sysv/linux/mips/clone3.S b/sysdeps/unix/sysv/linux/mips/clone3.S
> new file mode 100644
> index 0000000000..492d6d8b77
> --- /dev/null
> +++ b/sysdeps/unix/sysv/linux/mips/clone3.S
> @@ -0,0 +1,139 @@
> +/* The clone3 syscall wrapper. Linux/mips version.
> + Copyright (C) 2023 Free Software Foundation, Inc.
> +
> + This file is part of the GNU C Library.
> +
> + The GNU C Library is free software; you can redistribute it and/or
> + modify it under the terms of the GNU Lesser General Public
> + License as published by the Free Software Foundation; either
> + version 2.1 of the License, or (at your option) any later version.
> +
> + The GNU C Library is distributed in the hope that it will be useful,
> + but WITHOUT ANY WARRANTY; without even the implied warranty of
> + MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
> + Lesser General Public License for more details.
> +
> + You should have received a copy of the GNU Lesser General Public
> + License along with the GNU C Library; if not, see
> + <https://www.gnu.org/licenses/>. */
> +
> +#include <sys/asm.h>
> +#include <sysdep.h>
> +#define _ERRNO_H 1
> +#include <bits/errno.h>
> +
> +/* The userland implementation is:
> + int clone3 (struct clone_args *cl_args, size_t size,
> + int (*func)(void *arg), void *arg);
> +
> + the kernel entry is:
> + int clone3 (struct clone_args *cl_args, size_t size);
> +
> + The parameters are passed in registers from userland:
> + a0/$4: cl_args
> + a1/$5: size
> + a2/$6: func
> + a3/$7: arg */
> +
> + .text
> + .set nomips16
> +#if _MIPS_SIM == _ABIO32
> +# define EXTRA_LOCALS 1
> +#else
> +# define EXTRA_LOCALS 0
> +#endif
> +#define FRAMESZ ((NARGSAVE*SZREG)+ALSZ)&ALMASK
> +GPOFF= FRAMESZ-(1*SZREG)
> +NESTED(__clone3, SZREG, sp)
> +#ifdef __PIC__
> + SETUP_GP
> +#endif
> +#if FRAMESZ
> + PTR_SUBU sp, FRAMESZ
> + cfi_adjust_cfa_offset (FRAMESZ)
> +#endif
> + SETUP_GP64_STACK (GPOFF, __clone)
> +#ifdef __PIC__
> + SAVE_GP (GPOFF)
> +#endif
> +#ifdef PROF
> + .set noat
> + move $1,ra
> + jal _mcount
> + .set at
> +#endif
> +
> + /* Sanity check args. */
> + li v0, EINVAL
> + beqz a0, L(error) /* No NULL cl_args pointer. */
> + beqz a2, L(error) /* No NULL function pointer. */
> +
> + move $8, a3 /* a3 is set to 0/1 for syscall success/error
> + while a4/$8 is returned unmodified. */
> +
> + /* Do the system call, the kernel expects:
> + v0: system call number
> + a0: cl_args
> + a1: size */
> + li v0, __NR_clone3
> + cfi_endproc
> + syscall
> +
> + bnez a3, L(error)
> + beqz v0, L(thread_start_clone3)
> +
> + /* Successful return from the parent */
> + cfi_startproc
> +#if FRAMESZ
> + cfi_adjust_cfa_offset (FRAMESZ)
> +#endif
> + SETUP_GP64_STACK_CFI (GPOFF)
> + cfi_remember_state
> + RESTORE_GP64_STACK
> +#if FRAMESZ
> + PTR_ADDU sp, FRAMESZ
> + cfi_adjust_cfa_offset (-FRAMESZ)
> +#endif
> + ret
> +
> +L(error):
> + cfi_restore_state
> +#ifdef __PIC__
> + PTR_LA t9,__syscall_error
> + RESTORE_GP64_STACK
> + PTR_ADDU sp, FRAMESZ
> + cfi_adjust_cfa_offset (-FRAMESZ)
> + jr t9
> +#else
> + RESTORE_GP64_STACK
> + PTR_ADDU sp, FRAMESZ
> + cfi_adjust_cfa_offset (-FRAMESZ)
> + j __syscall_error
> +#endif
> +END (__clone3)
> +
> +/* Load up the arguments to the function. Put this block of code in
> + its own function so that we can terminate the stack trace with our
> + debug info. */
> +
> +ENTRY(__thread_start_clone3)
> +L(thread_start_clone3):
> + cfi_undefined ($31)
> + /* cp is already loaded. */
> + SAVE_GP (GPOFF)
> + /* The stackframe has been created on entry of clone3. */
> +
> + /* Restore the arg for user's function. */
> + move t9, a2 /* Function pointer. */
> + move a0, $8 /* Argument pointer. */
> +
> + /* Call the user's function. */
> + jal t9
> +
> + move a0, v0
> + li v0, __NR_exit
> + syscall
> +END(__thread_start_clone3)
> +
> +libc_hidden_def (__clone3)
> +weak_alias (__clone3, clone3)
> diff --git a/sysdeps/unix/sysv/linux/mips/sysdep.h b/sysdeps/unix/sysv/linux/mips/sysdep.h
> index ff84a91b31..673aa08b57 100644
> --- a/sysdeps/unix/sysv/linux/mips/sysdep.h
> +++ b/sysdeps/unix/sysv/linux/mips/sysdep.h
> @@ -28,3 +28,5 @@
> #endif
> #define HAVE_GETTIMEOFDAY_VSYSCALL "__vdso_gettimeofday"
> #define HAVE_CLOCK_GETRES_VSYSCALL "__vdso_clock_getres"
> +
> +#define HAVE_CLONE3_WRAPPER 1
prev parent reply other threads:[~2023-05-25 17:36 UTC|newest]
Thread overview: 13+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-02-03 17:12 [PATCH 0/5] Add clone3 support for multiple architectures Adhemerval Zanella
2023-02-03 17:12 ` [PATCH 1/5] powerpc64: Add the clone3 wrapper Adhemerval Zanella
2023-02-03 21:13 ` Paul E Murphy
2023-02-03 17:12 ` [PATCH 2/5] s390x: " Adhemerval Zanella
2023-05-25 17:36 ` Adhemerval Zanella Netto
2023-02-03 17:12 ` [PATCH 3/5] riscv: " Adhemerval Zanella
2023-05-25 17:36 ` Adhemerval Zanella Netto
2023-05-29 14:04 ` Palmer Dabbelt
2023-05-29 20:38 ` Adhemerval Zanella Netto
2023-02-03 17:12 ` [PATCH 4/5] arm: " Adhemerval Zanella
2023-05-25 17:36 ` Adhemerval Zanella Netto
2023-02-03 17:12 ` [PATCH 5/5] mips: " Adhemerval Zanella
2023-05-25 17:36 ` Adhemerval Zanella Netto [this message]
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=f27d3bb6-a502-d3cc-a00e-d4c31c22abe5@linaro.org \
--to=adhemerval.zanella@linaro.org \
--cc=libc-alpha@sourceware.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).