public inbox for gdb-cvs@sourceware.org
help / color / mirror / Atom feed
* [binutils-gdb] New testcase gdb.threads/leader-exit-attach.exp (PR threads/8153)
@ 2024-04-12 17:45 Pedro Alves
0 siblings, 0 replies; only message in thread
From: Pedro Alves @ 2024-04-12 17:45 UTC (permalink / raw)
To: gdb-cvs
https://sourceware.org/git/gitweb.cgi?p=binutils-gdb.git;h=ec48903170926f3827144525b50ddd3c6ae3fbf0
commit ec48903170926f3827144525b50ddd3c6ae3fbf0
Author: Pedro Alves <pedro@palves.net>
Date: Mon Mar 25 15:17:02 2024 +0000
New testcase gdb.threads/leader-exit-attach.exp (PR threads/8153)
Add a new testcase for exercising attaching to a process after its
main thread has exited.
This is not possible on Linux, the kernel does not allow attaching to
a zombie task, so the test is kfailed there. It is possible however
on Windows at least, and was the scenario addressed by the Windows
backend fix in
https://sourceware.org/legacy-ml/gdb-patches/2003-12/msg00479.html,
nowadays PR threads/8153, back in 2003.
Passes cleanly on Cygwin.
KFAILed on GNU/Linux native and gdbserver.
Bug: https://sourceware.org/bugzilla/show_bug.cgi?id=8153
Bug: https://sourceware.org/bugzilla/show_bug.cgi?id=31554
Bug: https://sourceware.org/bugzilla/show_bug.cgi?id=31555
Change-Id: Ib554f92f68c965bb4603cdf2aadb55ca45ded53b
Diff:
---
gdb/testsuite/gdb.threads/leader-exit-attach.exp | 87 ++++++++++++++++++++++++
1 file changed, 87 insertions(+)
diff --git a/gdb/testsuite/gdb.threads/leader-exit-attach.exp b/gdb/testsuite/gdb.threads/leader-exit-attach.exp
new file mode 100644
index 00000000000..c1ed1baaa67
--- /dev/null
+++ b/gdb/testsuite/gdb.threads/leader-exit-attach.exp
@@ -0,0 +1,87 @@
+# Copyright (C) 2024 Free Software Foundation, Inc.
+
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 3 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+# Test attaching to a program after its main thread has exited.
+
+require can_spawn_for_attach
+
+standard_testfile leader-exit.c
+
+if {[build_executable "failed to prepare" $testfile $srcfile {debug pthreads}] == -1} {
+ return
+}
+
+set escapedbinfile [string_to_regexp ${binfile}]
+
+set test_spawn_id [spawn_wait_for_attach $binfile]
+set testpid [spawn_id_get_pid $test_spawn_id]
+
+# Wait a bit for the leader thread to exit, before attaching.
+sleep 2
+
+clean_restart ${binfile}
+
+# Save this early as we may not be able to talk with GDBserver anymore
+# when we need to check it.
+set is_gdbserver [target_is_gdbserver]
+
+# True if successfully attached.
+set attached 0
+
+gdb_test_multiple "attach $testpid" "attach" {
+ -re "Attaching to process $testpid failed.*" {
+ # GNU/Linux gdbserver. Linux ptrace does not let you attach
+ # to zombie threads.
+ setup_kfail "gdb/31555" *-*-linux*
+ fail $gdb_test_name
+ }
+ -re "warning: process $testpid is a zombie - the process has already terminated.*" {
+ # Native GNU/Linux. Linux ptrace does not let you attach to
+ # zombie threads.
+ setup_kfail "gdb/31555" *-*-linux*
+ fail $gdb_test_name
+ }
+ -re "Attaching to program: $escapedbinfile, process $testpid.*$gdb_prompt $" {
+ pass $gdb_test_name
+ set attached 1
+ }
+}
+
+# With gdbserver, after we failed to attach, we hit PR server/31554:
+# print $_inferior_thread_count
+# Remote connection closed
+# (gdb) KFAIL: gdb.threads/leader-exit-attach.exp: get valueof "$_inferior_thread_count"
+if {!$attached && $is_gdbserver} {
+ setup_kfail "server/31554" "*-*-*"
+}
+
+set thread_count [get_valueof "" "\$_inferior_thread_count" -1]
+
+if {$thread_count == -1} {
+ kill_wait_spawned_process $test_spawn_id
+ return
+}
+
+if {$attached} {
+ # Check that we have at least one thread. We can't assume there
+ # will only be exactly one thread, because on some systems, like
+ # Cygwin, the runtime spawns extra threads. Also, on Windows,
+ # attaching always injects one extra thread.
+ gdb_assert {$thread_count >= 1}
+} else {
+ gdb_assert {$thread_count == 0}
+}
+
+kill_wait_spawned_process $test_spawn_id
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2024-04-12 17:45 UTC | newest]
Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2024-04-12 17:45 [binutils-gdb] New testcase gdb.threads/leader-exit-attach.exp (PR threads/8153) Pedro Alves
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).