[PATCH] vfork patch for SH (Take 2)

[PATCH] vfork patch for SH (Take 2)

[kaz Kojima]

Hi,

Here is the revised patch for vfork fix of SH and adding
correct syscall error handling for non-PIC case.

Regards,
	kaz
--
2003-01-11  Kaz Kojima  <kkojima@rr.iij4u.or.jp>

[ChangeLog]
	* sysdeps/unix/sysv/linux/sh/sysdep.h (SYSCALL_ERROR_HANDLER): 
	Add non-PIC case.

[linuxthreads/ChangeLog]
	* sysdeps/unix/sysv/linux/sh/vfork.S: New file.

diff -urN ORIG/libc/sysdeps/unix/sysv/linux/sh/sysdep.h LOCAL/libc/sysdeps/unix/sysv/linux/sh/sysdep.h
--- ORIG/libc/sysdeps/unix/sysv/linux/sh/sysdep.h	Wed Jan  8 08:37:36 2003
+++ LOCAL/libc/sysdeps/unix/sysv/linux/sh/sysdep.h	Sat Jan 11 10:07:19 2003
@@ -66,7 +66,12 @@
   END (name)
 
 #ifndef PIC
-# define SYSCALL_ERROR_HANDLER	/* Nothing here; code in sysdep.S is used.  */
+# define SYSCALL_ERROR_HANDLER	\
+	mov.l 0f,r1; \
+	jmp @r1; \
+	 mov r0,r4; \
+	.align 2; \
+     0: .long __syscall_error
 #else
 # if RTLD_PRIVATE_ERRNO
 #  define SYSCALL_ERROR_HANDLER	\
diff -urN ORIG/libc/linuxthreads/sysdeps/unix/sysv/linux/sh/vfork.S LOCAL/libc/linuxthreads/sysdeps/unix/sysv/linux/sh/vfork.S
--- ORIG/libc/linuxthreads/sysdeps/unix/sysv/linux/sh/vfork.S	Thu Jan  1 09:00:00 1970
+++ LOCAL/libc/linuxthreads/sysdeps/unix/sysv/linux/sh/vfork.S	Sat Jan 11 10:43:53 2003
@@ -0,0 +1,57 @@
+/* Copyright (C) 2003 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep-cancel.h>
+#define _ERRNO_H	1
+#include <bits/errno.h>
+
+/* Clone the calling process, but without copying the whole address space.
+   The calling process is suspended until the new process exits or is
+   replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
+   and the process ID of the new process to the old process.  */
+
+ENTRY (__vfork)
+	SINGLE_THREAD_P
+	bf .Lhidden_fork
+
+	mov.w	.L1, r3
+	trapa	#0x10
+	mov     r0, r1
+	mov	#-12, r2
+	shad	r2, r1
+	not	r1, r1			// r1=0 means r0 = -1 to -4095
+	tst	r1, r1			// i.e. error in linux
+	bf	.Lpseudo_end
+	SYSCALL_ERROR_HANDLER
+.Lpseudo_end:
+	rts
+	 nop
+.L1:	.word	__NR_vfork
+
+.Lhidden_fork:	
+	mov.l	.L2, r1
+	braf	r1
+	 nop
+1:
+	.align 2
+.L2:	.long	HIDDEN_JUMPTARGET(__fork)-1b
+
+PSEUDO_END (__vfork)
+libc_hidden_def (__vfork)
+
+weak_alias (__vfork, vfork)

Re: [PATCH] vfork patch for SH (Take 2)

[Ulrich Drepper]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

kaz Kojima wrote:

> Here is the revised patch for vfork fix of SH and adding
> correct syscall error handling for non-PIC case.

Thanks, I've applied it.

- -- 
- --------------.                        ,-.            444 Castro Street
Ulrich Drepper \    ,-----------------'   \ Mountain View, CA 94041 USA
Red Hat         `--' drepper at redhat.com `---------------------------
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.2.1 (GNU/Linux)

iD8DBQE+IS7r2ijCOnn/RHQRArwAAJ9HV0v8QBP9ZNbuBlaZPr7Qxr/PhACfWRgp
KA+dK3BC0IxfXPA/4kRitYg=
=gFA1
-----END PGP SIGNATURE-----