arm mmap improvements

arm mmap improvements

[Philip Blundell]

[-- Attachment #1: Type: text/plain, Size: 95 bytes --]

This patch contains a couple of performance improvements for mmap() and
mmap64() on arm.

p.



[-- Attachment #2: mmap.diff --]
[-- Type: text/plain, Size: 3974 bytes --]

2003-09-14  Philip Blundell  <philb@gnu.org>

	* sysdeps/unix/sysv/linux/arm/mmap.S: Use sys_mmap2 if it's known
	to be available.

	* sysdeps/unix/sysv/linux/arm/mmap2.S: Optimise code a little.

Index: sysdeps/unix/sysv/linux/arm/mmap.S
===================================================================
RCS file: /cvs/glibc/libc/sysdeps/unix/sysv/linux/arm/mmap.S,v
retrieving revision 1.5
diff -u -r1.5 mmap.S
--- sysdeps/unix/sysv/linux/arm/mmap.S	6 Jul 2001 04:56:13 -0000	1.5
+++ sysdeps/unix/sysv/linux/arm/mmap.S	14 Sep 2003 17:18:27 -0000
@@ -1,4 +1,4 @@
-/* Copyright (C) 1998, 2000 Free Software Foundation, Inc.
+/* Copyright (C) 1998, 2000, 2003 Free Software Foundation, Inc.
    This file is part of the GNU C Library.
 
    The GNU C Library is free software; you can redistribute it and/or
@@ -17,11 +17,47 @@
    02111-1307 USA.  */
 
 #include <sysdep.h>
+#include <kernel-features.h>
+
+#define	EINVAL		22
 
 	.text
 
 ENTRY (__mmap)
+# ifdef __ASSUME_MMAP2_SYSCALL
+	/* This code is actually a couple of cycles slower than the
+	   sys_mmap version below, so it might seem like a loss.  But the
+	   code path inside the kernel is sufficiently much shorter to
+	   make it a net gain to use mmap2 when it's known to be
+	   available.  */
+
+	/* shuffle args */
+	str	r5, [sp, #-4]!
+	ldr	r5, [sp, #8]
+	str	r4, [sp, #-4]!
+	ldr	r4, [sp, #8]
+
+	/* convert offset to pages */
+	movs	ip, r5, lsl #20
+	bne	.Linval
+	mov	r5, r5, lsr #12
+	
+	/* do the syscall */
+	swi	SYS_ify (mmap2)
+
+	/* restore registers */
+2:
+	ldr	r4, [sp], #4
+	ldr	r5, [sp], #4
+
+	cmn	r0, $4096
+	RETINSTR(movcc, pc, lr)
+	b	PLTJMP(syscall_error)
 
+.Linval:
+	mov	r0, #-EINVAL
+	b	2b
+# else
 	/* Because we can only get five args through the syscall interface, and
 	   mmap() takes six, we need to build a parameter block and pass its
 	   address instead.  The 386 port does a similar trick.  */
@@ -49,6 +85,7 @@
 	cmn	r0, $4096
 	RETINSTR(movcc, pc, lr)
 	b	PLTJMP(syscall_error);
+#endif
 
 PSEUDO_END (__mmap)
 
Index: sysdeps/unix/sysv/linux/arm/mmap64.S
===================================================================
RCS file: /cvs/glibc/libc/sysdeps/unix/sysv/linux/arm/mmap64.S,v
retrieving revision 1.5
diff -u -r1.5 mmap64.S
--- sysdeps/unix/sysv/linux/arm/mmap64.S	27 Mar 2003 02:45:46 -0000	1.5
+++ sysdeps/unix/sysv/linux/arm/mmap64.S	14 Sep 2003 17:18:27 -0000
@@ -27,38 +27,44 @@
 	.text
 ENTRY (__mmap64)
 #ifdef __NR_mmap2
-	stmfd	sp!, {r4, r5, lr}
-	ldr	r5, [sp, $16]
-	ldr	r4, [sp, $12]
-	movs	ip, r5, lsl $20		@ check that offset is page-aligned
+	ldr	ip, [sp, $4]		@ offset low part
+	str	r5, [sp, #-4]!
+	ldr	r5, [sp, $12]		@ offset high part
+	str	r4, [sp, #-4]!
+	movs	r4, ip, lsl $20		@ check that offset is page-aligned
+	mov	ip, ip, lsr $12
+	moveqs	r4, r5, lsr $12		@ check for overflow
 	bne	.Linval
-	ldr	ip, [sp, $20]
-	mov	r5, r5, lsr $12
-	orr	r5, r5, ip, lsl $20	@ compose page offset
-	movs	ip, ip, lsr $12
-	bne	.Linval			@ check for overflow
+	ldr	r4, [sp, $8]		@ load fd
+	orr	r5, ip, r5, lsl $20	@ compose page offset
 	mov	ip, r0
 	swi	SYS_ify (mmap2)
 	cmn	r0, $4096
-	LOADREGS(ccfd, sp!, {r4, r5, pc})
 # ifdef __ASSUME_MMAP2_SYSCALL
-	ldmfd	sp!, {r4, r5, lr}
+	ldr	r4, [sp], #4
+	ldr	r5, [sp], #4
+	RETINSTR(movcc, pc, lr)	
 	b	PLTJMP(syscall_error)
 # else
+	ldrcc	r4, [sp], #4
+	ldrcc	r5, [sp], #4
+	RETINSTR(movcc, pc, lr)
 	cmn	r0, $ENOSYS
-	ldmnefd	sp!, {r4, r5, lr}
-	bne	PLTJMP(syscall_error)
+	bne	.Lerror
 	/* The current kernel does not support mmap2.  Fall back to plain
 	   mmap if the offset is small enough.  */
-	ldr	r5, [sp, $20]
+	ldr	r5, [sp, $16]
 	mov	r0, ip			@ first arg was clobbered
 	teq	r5, $0
-	ldmeqfd	sp!, {r4, r5, lr}
+	ldreq	r4, [sp], #4
+	ldreq	r5, [sp], #4
 	beq	PLTJMP(__mmap)
 # endif
 .Linval:
 	mov	r0, $-EINVAL
-	ldmfd	sp!, {r4, r5, lr}
+.Lerror:
+	ldr	r4, [sp], #4
+	ldr	r5, [sp], #4
 	b	PLTJMP(syscall_error)
 #else
 	/* The kernel headers do not support mmap2.  Fall back to plain

Re: arm mmap improvements

[Ulrich Drepper]

Philip Blundell wrote:
> This patch contains a couple of performance improvements for mmap() and
> mmap64() on arm.

I've applied this and the memset patch.  Thanks,

-- 
--------------.                        ,-.            444 Castro Street
Ulrich Drepper \    ,-----------------'   \ Mountain View, CA 94041 USA
Red Hat         `--' drepper at redhat.com `---------------------------