From: Richard Henderson <rth@twiddle.net>
To: libc-ports@sourceware.org
Cc: Joseph Myers <joseph@codesourcery.com>
Subject: [PATCH 26/26] arm: Add optimized add_n and sub_n
Date: Wed, 27 Feb 2013 03:17:00 -0000 [thread overview]
Message-ID: <1361934986-17018-27-git-send-email-rth@twiddle.net> (raw)
In-Reply-To: <1361934986-17018-1-git-send-email-rth@twiddle.net>
Written from scratch rather than copied from GMP, due to GPL 2.1 vs
GPL 3, but tested with the GMP testsuite.
This is 250% faster than the generic code as measured on Cortex-A15,
and the same speed as GMP on the same core, and probably everywhere.
---
* sysdeps/arm/add_n.S: New file.
* sysdeps/arm/sub_n.S: New file.
---
ports/sysdeps/arm/add_n.S | 83 +++++++++++++++++++++++++++++++++++++++++++++++
ports/sysdeps/arm/sub_n.S | 2 ++
2 files changed, 85 insertions(+)
create mode 100644 ports/sysdeps/arm/add_n.S
create mode 100644 ports/sysdeps/arm/sub_n.S
diff --git a/ports/sysdeps/arm/add_n.S b/ports/sysdeps/arm/add_n.S
new file mode 100644
index 0000000..bbfb701
--- /dev/null
+++ b/ports/sysdeps/arm/add_n.S
@@ -0,0 +1,83 @@
+/* Copyright (C) 2013 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library. If not, see
+ <http://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+
+ .syntax unified
+ .text
+
+#ifdef USE_AS_SUB_N
+# define INITC cmp r0, r0
+# define OPC sbcs
+# define RETC s(sbc) r0, r0, r0; s(neg) r0, r0
+# define FUNC __mpn_sub_n
+#else
+# define INITC cmn r0, #0
+# define OPC adcs
+# define RETC s(mov) r0, #0; s(adc) r0, r0, r0
+# define FUNC __mpn_add_n
+#endif
+
+/* mp_limb_t mpn_add_n(res_ptr, src1_ptr, src2_ptr, size) */
+
+ENTRY(FUNC)
+ push { r4, r5, r6, r7, r8, r9, lr }
+ cfi_adjust_cfa_offset (28)
+ cfi_rel_offset (r4, 0)
+ cfi_rel_offset (r5, 4)
+ cfi_rel_offset (r6, 8)
+ cfi_rel_offset (r7, 12)
+ cfi_rel_offset (r8, 16)
+ cfi_rel_offset (r9, 20)
+ cfi_rel_offset (lr, 24)
+
+ INITC /* initialize carry flag */
+ tst r3, #1 /* count & 1 == 1? */
+ add lr, r1, r3, lsl #2 /* compute end src1 */
+ beq 1f
+
+ ldr r4, [r1], #4 /* do one to make count even */
+ ldr r5, [r2], #4
+ OPC r4, r4, r5
+ teq r1, lr /* end of count? (preserve carry) */
+ str r4, [r0], #4
+ beq 9f
+1:
+ tst r3, #2 /* count & 2 == 2? */
+ beq 2f
+ ldm r1!, { r4, r5 } /* do two to make count 0 mod 4 */
+ ldm r2!, { r6, r7 }
+ OPC r4, r4, r6
+ OPC r5, r5, r7
+ teq r1, lr /* end of count? */
+ stm r0!, { r4, r5 }
+ beq 9f
+2:
+ ldm r1!, { r3, r4, r5, r6 } /* do four each loop */
+ ldm r2!, { r7, r8, r9, ip }
+ OPC r3, r3, r7
+ OPC r4, r4, r8
+ OPC r5, r5, r9
+ OPC r6, r6, ip
+ teq r1, lr
+ stm r0!, { r3, r4, r5, r6 }
+ bne 2b
+
+9:
+ RETC /* copy carry out */
+ pop { r4, r5, r6, r7, r8, r9, pc }
+END(FUNC)
diff --git a/ports/sysdeps/arm/sub_n.S b/ports/sysdeps/arm/sub_n.S
new file mode 100644
index 0000000..8eafa41
--- /dev/null
+++ b/ports/sysdeps/arm/sub_n.S
@@ -0,0 +1,2 @@
+#define USE_AS_SUB_N
+#include "add_n.S"
--
1.8.1.2
next prev parent reply other threads:[~2013-02-27 3:17 UTC|newest]
Thread overview: 63+ messages / expand[flat|nested] mbox.gz Atom feed top
2013-02-27 3:16 [PATCH 00/26] ARM improvements Richard Henderson
2013-02-27 3:16 ` [PATCH 04/26] arm: Include libc-do-syscall in sysdep-rtld-routines Richard Henderson
2013-02-28 0:15 ` Joseph S. Myers
2013-02-27 3:16 ` [PATCH 09/26] arm: Mark assembly files that will not use thumb mode Richard Henderson
2013-02-28 0:58 ` Joseph S. Myers
2013-02-27 3:16 ` [PATCH 01/26] Sync config.guess and config.sub with upstream Richard Henderson
2013-02-27 17:03 ` Joseph S. Myers
2013-02-27 3:16 ` [PATCH 05/26] arm: Introduce thumb helpers s and pc_ofs Richard Henderson
2013-02-28 0:20 ` Joseph S. Myers
2013-02-28 0:36 ` Richard Henderson
2013-02-28 1:45 ` Måns Rullgård
2013-02-27 3:16 ` [PATCH 03/26] arm: Handle armv6 in preconfigure Richard Henderson
2013-02-27 18:02 ` Joseph S. Myers
2013-02-27 18:04 ` Roland McGrath
2013-02-27 18:08 ` Richard Henderson
2013-02-27 18:34 ` Richard Henderson
2013-02-27 19:57 ` Joseph S. Myers
2013-02-27 3:17 ` [PATCH 02/26] arm: Update preconfigure fragment for gcc 4.8 Richard Henderson
2013-02-27 17:54 ` Joseph S. Myers
2013-02-27 18:11 ` Richard Henderson
2013-02-27 3:17 ` [PATCH 25/26] arm: Add optimized submul_1 Richard Henderson
2013-02-27 3:17 ` [PATCH 06/26] arm: Use pc_ofs Richard Henderson
2013-02-28 0:21 ` Joseph S. Myers
2013-02-27 3:17 ` Richard Henderson [this message]
2013-02-27 3:17 ` [PATCH 10/26] arm: Introduce and use LDST_PCREL Richard Henderson
2013-02-28 1:00 ` Joseph S. Myers
2013-02-27 3:17 ` [PATCH 22/26] arm: Implement armv6t2 optimized strchr, strrchr, rawmemchr Richard Henderson
2013-02-28 1:31 ` Joseph S. Myers
2013-02-27 3:17 ` [PATCH 24/26] arm: Add optimized addmul_1 Richard Henderson
2013-02-28 13:58 ` Måns Rullgård
2013-02-28 18:19 ` Richard Henderson
2013-02-28 19:37 ` Måns Rullgård
2013-02-27 3:17 ` [PATCH 21/26] arm: Implement armv6t2 optimized strcpy Richard Henderson
2013-02-27 3:17 ` [PATCH 08/26] arm: Add IT insns for thumb mode Richard Henderson
2013-02-28 0:41 ` Joseph S. Myers
2013-02-27 3:17 ` [PATCH 16/26] arm: Commonize BX conditionals Richard Henderson
2013-02-28 21:51 ` Joseph S. Myers
2013-02-27 3:17 ` [PATCH 15/26] arm: Delete LOADREGS macro Richard Henderson
2013-02-28 1:24 ` Joseph S. Myers
2013-02-27 3:17 ` [PATCH 12/26] arm: Enable thumb2 mode in assembly files Richard Henderson
2013-02-27 3:17 ` [PATCH 19/26] arm: Add optimized ffs for armv6t2 Richard Henderson
2013-02-27 15:51 ` Måns Rullgård
2013-02-27 16:34 ` Richard Henderson
2013-02-27 17:49 ` Roland McGrath
2013-02-27 3:17 ` [PATCH 13/26] arm: Store lr in r2 around GET_TLS Richard Henderson
2013-02-27 3:17 ` [PATCH 18/26] arm: Use GET_TLS more often Richard Henderson
2013-02-28 21:59 ` Joseph S. Myers
2013-02-27 3:17 ` [PATCH 11/26] arm: Introduce and use NEGOFF series of macros Richard Henderson
2013-02-27 3:17 ` [PATCH 17/26] arm: Unless arm4t, pop return address directly into pc Richard Henderson
2013-02-28 21:57 ` Joseph S. Myers
2013-02-27 3:17 ` [PATCH 20/26] arm: Implement armv6t2 optimized strlen Richard Henderson
2013-02-27 17:12 ` Måns Rullgård
2013-02-27 17:44 ` Richard Henderson
2013-02-27 3:17 ` [PATCH 23/26] arm: Rewrite armv6t2 memchr with uqadd8 Richard Henderson
2013-02-27 7:04 ` Richard Henderson
2013-02-27 3:17 ` [PATCH 07/26] arm: Introduce and use GET_TLS Richard Henderson
2013-02-28 0:34 ` Joseph S. Myers
2013-02-27 3:17 ` [PATCH 14/26] arm: Use push/pop mnemonics Richard Henderson
2013-02-28 1:03 ` Joseph S. Myers
2013-02-27 15:41 ` [PATCH 00/26] ARM improvements Måns Rullgård
2013-02-27 16:59 ` Joseph S. Myers
2013-02-27 17:34 ` Richard Henderson
2013-02-28 22:05 ` Joseph S. Myers
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1361934986-17018-27-git-send-email-rth@twiddle.net \
--to=rth@twiddle.net \
--cc=joseph@codesourcery.com \
--cc=libc-ports@sourceware.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).