From: Adhemerval Zanella <adhemerval.zanella@linaro.org>
To: libc-alpha@sourceware.org
Subject: [PATCH v5 08/22] sparc: Fix Race conditions in pthread cancellation [BZ#12683]
Date: Mon, 10 Apr 2023 16:58:53 -0300 [thread overview]
Message-ID: <20230410195907.4123869-9-adhemerval.zanella@linaro.org> (raw)
In-Reply-To: <20230410195907.4123869-1-adhemerval.zanella@linaro.org>
By adding the required syscall_cancel.S.
Checked on sparc64-linux-gnu and sparcv9-linux-gnu.
---
.../sysv/linux/sparc/sparc32/syscall_cancel.S | 71 ++++++++++++++++++
.../sysv/linux/sparc/sparc64/syscall_cancel.S | 74 +++++++++++++++++++
2 files changed, 145 insertions(+)
create mode 100644 sysdeps/unix/sysv/linux/sparc/sparc32/syscall_cancel.S
create mode 100644 sysdeps/unix/sysv/linux/sparc/sparc64/syscall_cancel.S
diff --git a/sysdeps/unix/sysv/linux/sparc/sparc32/syscall_cancel.S b/sysdeps/unix/sysv/linux/sparc/sparc32/syscall_cancel.S
new file mode 100644
index 0000000000..aa5c658ce1
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/sparc/sparc32/syscall_cancel.S
@@ -0,0 +1,71 @@
+/* Cancellable syscall wrapper. Linux/sparc32 version.
+ Copyright (C) 2023 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+#include <descr-const.h>
+
+/* long int __syscall_cancel_arch (int *cancelhandling,
+ long int nr,
+ long int arg1,
+ long int arg2,
+ long int arg3,
+ long int arg4,
+ long int arg5,
+ long int arg6) */
+
+ENTRY (__syscall_cancel_arch)
+ save %sp, -96, %sp
+
+ cfi_window_save
+ cfi_register (%o7, %i7)
+ cfi_def_cfa_register (%fp)
+
+ .globl __syscall_cancel_arch_start
+__syscall_cancel_arch_start:
+
+ /* if (*cancelhandling & CANCELED_BITMASK)
+ __syscall_do_cancel() */
+ ld [%i0], %g2
+ andcc %g2, TCB_CANCELED_BITMASK, %g0
+ bne,pn %icc, 2f
+ /* Issue a 6 argument syscall. */
+ mov %i1, %g1
+ mov %i2, %o0
+ mov %i3, %o1
+ mov %i4, %o2
+ mov %i5, %o3
+ ld [%fp+92], %o4
+ ld [%fp+96], %o5
+ ta 0x10
+
+ .globl __syscall_cancel_arch_end
+__syscall_cancel_arch_end:
+ bcc 1f
+ nop
+ sub %g0, %o0, %o0
+1:
+ mov %o0, %i0
+ return %i7+8
+ nop
+
+2:
+ call __syscall_do_cancel, 0
+ nop
+ nop
+
+END (__syscall_cancel_arch)
diff --git a/sysdeps/unix/sysv/linux/sparc/sparc64/syscall_cancel.S b/sysdeps/unix/sysv/linux/sparc/sparc64/syscall_cancel.S
new file mode 100644
index 0000000000..21b0728d5a
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/sparc/sparc64/syscall_cancel.S
@@ -0,0 +1,74 @@
+/* Cancellable syscall wrapper. Linux/sparc64 version.
+ Copyright (C) 2023 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+#include <descr-const.h>
+
+ .register %g2, #scratch
+
+/* long int __syscall_cancel_arch (int *cancelhandling,
+ long int nr,
+ long int arg1,
+ long int arg2,
+ long int arg3,
+ long int arg4,
+ long int arg5,
+ long int arg6) */
+
+ENTRY (__syscall_cancel_arch)
+ save %sp, -176, %sp
+
+ cfi_window_save
+ cfi_register (%o7, %i7)
+ cfi_def_cfa_register (%fp)
+
+ .globl __syscall_cancel_arch_start
+__syscall_cancel_arch_start:
+
+ /* if (*cancelhandling & CANCELED_BITMASK)
+ __syscall_do_cancel() */
+ lduw [%i0], %g2
+ andcc %g2, TCB_CANCELED_BITMASK, %g0
+ bne,pn %xcc, 2f
+ /* Issue a 6 argument syscall. */
+ mov %i1, %g1
+ mov %i2, %o0
+ mov %i3, %o1
+ mov %i4, %o2
+ mov %i5, %o3
+ ldx [%fp + STACK_BIAS + 176], %o4
+ ldx [%fp + STACK_BIAS + 184], %o5
+ ta 0x6d
+
+ .global __syscall_cancel_arch_end
+__syscall_cancel_arch_end:
+
+ bcc,pt %xcc, 1f
+ nop
+ sub %g0, %o0, %o0
+1:
+ mov %o0, %i0
+ return %i7+8
+ nop
+
+2:
+ call __syscall_do_cancel, 0
+ nop
+ nop
+
+END (__syscall_cancel_arch)
--
2.34.1
next prev parent reply other threads:[~2023-04-10 19:59 UTC|newest]
Thread overview: 34+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-04-10 19:58 [PATCH v5 00/22] " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 01/22] nptl: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 02/22] x86_64: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 03/22] x32: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 04/22] i386: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 05/22] aarch64: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 06/22] arm: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 07/22] powerpc: " Adhemerval Zanella
2023-04-14 15:27 ` Paul E Murphy
2023-04-27 11:13 ` Adhemerval Zanella Netto
2023-04-10 19:58 ` Adhemerval Zanella [this message]
2023-04-10 20:46 ` [PATCH v5 09/22] s390: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 10/22] riscv: " Adhemerval Zanella
2023-04-11 6:35 ` Xi Ruoyao
2023-04-11 7:01 ` Xi Ruoyao
2023-04-11 13:49 ` Adhemerval Zanella Netto
2023-04-10 20:46 ` [PATCH v5 11/22] arc: Fix Race conditions in pthread cancellation [BZ #12683] Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 12/22] ia64: Fix Race conditions in pthread cancellation [BZ#12683] Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 13/22] sh: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 14/22] nios2: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 15/22] microblaze: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 16/22] hppa: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 17/22] m68k: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 18/22] alpha: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 19/22] csky: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 20/22] mips: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 21/22] or1k: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 22/22] loongarch: " Adhemerval Zanella
2023-04-11 6:19 ` Xi Ruoyao
2023-04-11 12:00 ` caiyinyu
2023-04-11 12:21 ` caiyinyu
2023-04-11 12:55 ` Xi Ruoyao
2023-04-11 13:54 ` Adhemerval Zanella Netto
2023-04-11 13:56 ` [PATCH v5 09/22] s390: " Stefan Liebler
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20230410195907.4123869-9-adhemerval.zanella@linaro.org \
--to=adhemerval.zanella@linaro.org \
--cc=libc-alpha@sourceware.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).