From: Adhemerval Zanella <adhemerval.zanella@linaro.org>
To: libc-alpha@sourceware.org
Subject: [PATCH v5 19/22] csky: Fix Race conditions in pthread cancellation [BZ#12683]
Date: Mon, 10 Apr 2023 17:46:11 -0300 [thread overview]
Message-ID: <20230410204614.4129551-11-adhemerval.zanella@linaro.org> (raw)
In-Reply-To: <20230410204614.4129551-1-adhemerval.zanella@linaro.org>
By adding the required syscall_cancel.S.
Checked against a build and make check run-built-tests=no for
csky-linux-gnuabiv2.
---
sysdeps/unix/sysv/linux/csky/syscall_cancel.S | 114 ++++++++++++++++++
1 file changed, 114 insertions(+)
create mode 100644 sysdeps/unix/sysv/linux/csky/syscall_cancel.S
diff --git a/sysdeps/unix/sysv/linux/csky/syscall_cancel.S b/sysdeps/unix/sysv/linux/csky/syscall_cancel.S
new file mode 100644
index 0000000000..2989765f8c
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/csky/syscall_cancel.S
@@ -0,0 +1,114 @@
+/* Cancellable syscall wrapper. Linux/csky version.
+ Copyright (C) 2023 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+#include <descr-const.h>
+
+/* long int __syscall_cancel_arch (int *cancelhandling,
+ __syscall_arg_t nr,
+ __syscall_arg_t arg1,
+ __syscall_arg_t arg2,
+ __syscall_arg_t arg3,
+ __syscall_arg_t arg4,
+ __syscall_arg_t arg5,
+ __syscall_arg_t arg6) */
+
+#ifdef SHARED
+# define STACK_ADJ 4
+#else
+# define STACK_ADJ 0
+#endif
+
+ENTRY (__syscall_cancel_arch)
+ subi sp, sp, 16 + STACK_ADJ
+ cfi_def_cfa_offset (16 + STACK_ADJ)
+#ifdef SHARED
+ st.w gb, (sp, 16)
+ lrw t1, 1f@GOTPC
+ cfi_offset (gb, -4)
+ grs gb, 1f
+1:
+#endif
+ st.w lr, (sp, 12)
+ st.w l3, (sp, 8)
+ st.w l1, (sp, 4)
+ st.w l0, (sp, 0)
+#ifdef SHARED
+ addu gb, gb, t1
+#endif
+ subi sp, sp, 16
+ cfi_def_cfa_offset (32 + STACK_ADJ)
+ cfi_offset (lr, -( 4 + STACK_ADJ))
+ cfi_offset (l3, -( 8 + STACK_ADJ))
+ cfi_offset (l1, -(12 + STACK_ADJ))
+ cfi_offset (l0, -(16 + STACK_ADJ))
+
+ mov l3, a1
+ mov a1, a3
+ ld.w a3, (sp, 32 + STACK_ADJ)
+ st.w a3, (sp, 0)
+ ld.w a3, (sp, 36 + STACK_ADJ)
+ st.w a3, (sp, 4)
+ ld.w a3, (sp, 40 + STACK_ADJ)
+ st.w a3, (sp, 8)
+ ld.w a3, (sp, 44 + STACK_ADJ)
+ st.w a3, (sp, 12)
+
+ .globl __syscall_cancel_arch_start
+__syscall_cancel_arch_start:
+ ld.w t0, (a0, 0)
+ andi t0, t0, TCB_CANCELED_BITMASK
+ jbnez t0, 2f
+ mov a0, a2
+ ld.w a3, (sp, 4)
+ ld.w a2, (sp, 0)
+ ld.w l0, (sp, 8)
+ ld.w l1, (sp, 12)
+ trap 0
+
+ .globl __syscall_cancel_arch_end
+__syscall_cancel_arch_end:
+ addi sp, sp, 16
+ cfi_remember_state
+ cfi_def_cfa_offset (16 + STACK_ADJ)
+#ifdef SHARED
+ ld.w gb, (sp, 16)
+ cfi_restore (gb)
+#endif
+ ld.w lr, (sp, 12)
+ cfi_restore (lr)
+ ld.w l3, (sp, 8)
+ cfi_restore (l3)
+ ld.w l1, (sp, 4)
+ cfi_restore (l1)
+ ld.w l0, (sp, 0)
+ cfi_restore (l0)
+ addi sp, sp, 16
+ cfi_def_cfa_offset (0)
+ rts
+
+2:
+ cfi_restore_state
+#ifdef SHARED
+ lrw a3, __syscall_do_cancel@GOTOFF
+ addu a3, a3, gb
+ jsr a3
+#else
+ jbsr __syscall_do_cancel
+#endif
+END (__syscall_cancel_arch)
--
2.34.1
next prev parent reply other threads:[~2023-04-10 20:46 UTC|newest]
Thread overview: 34+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-04-10 19:58 [PATCH v5 00/22] " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 01/22] nptl: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 02/22] x86_64: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 03/22] x32: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 04/22] i386: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 05/22] aarch64: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 06/22] arm: " Adhemerval Zanella
2023-04-10 19:58 ` [PATCH v5 07/22] powerpc: " Adhemerval Zanella
2023-04-14 15:27 ` Paul E Murphy
2023-04-27 11:13 ` Adhemerval Zanella Netto
2023-04-10 19:58 ` [PATCH v5 08/22] sparc: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 09/22] s390: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 10/22] riscv: " Adhemerval Zanella
2023-04-11 6:35 ` Xi Ruoyao
2023-04-11 7:01 ` Xi Ruoyao
2023-04-11 13:49 ` Adhemerval Zanella Netto
2023-04-10 20:46 ` [PATCH v5 11/22] arc: Fix Race conditions in pthread cancellation [BZ #12683] Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 12/22] ia64: Fix Race conditions in pthread cancellation [BZ#12683] Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 13/22] sh: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 14/22] nios2: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 15/22] microblaze: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 16/22] hppa: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 17/22] m68k: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 18/22] alpha: " Adhemerval Zanella
2023-04-10 20:46 ` Adhemerval Zanella [this message]
2023-04-10 20:46 ` [PATCH v5 20/22] mips: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 21/22] or1k: " Adhemerval Zanella
2023-04-10 20:46 ` [PATCH v5 22/22] loongarch: " Adhemerval Zanella
2023-04-11 6:19 ` Xi Ruoyao
2023-04-11 12:00 ` caiyinyu
2023-04-11 12:21 ` caiyinyu
2023-04-11 12:55 ` Xi Ruoyao
2023-04-11 13:54 ` Adhemerval Zanella Netto
2023-04-11 13:56 ` [PATCH v5 09/22] s390: " Stefan Liebler
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20230410204614.4129551-11-adhemerval.zanella@linaro.org \
--to=adhemerval.zanella@linaro.org \
--cc=libc-alpha@sourceware.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).