Re: [PATCH v5 22/22] loongarch: Fix Race conditions in pthread cancellation [BZ#12683]

[Xi Ruoyao <xry111@xry111.site>]

On Tue, 2023-04-11 at 20:00 +0800, caiyinyu wrote:
> 
> 在 2023/4/11 下午2:19, Xi Ruoyao 写道:
> > On Mon, 2023-04-10 at 17:46 -0300, Adhemerval Zanella via Libc-alpha
> > wrote:
> > 
> > /* snip */
> > 
> > > +1:
> > > +       addi.d  $r3,$r3,-16
> > > +       cfi_def_cfa_offset (16)
> > > +       st.d    $r1,$r3,8
> > > +       cfi_offset (1, -8)
> > > +       bl      __syscall_do_cancel
> > Can we simply use "b __syscall_do_cancel" for 1: like AArch64?
> 
> In LoongArch, the "b" instruction is equivalent to the "b" instruction
> in AArch64, and similarly,
> 
> the "bl" instruction in LoongArch is equivalent to the "bl"
> instruction 
> in AArch64.
> 
> > > +
> > > +END (__syscall_cancel_arch)

I've rewritten the syscall_cancel.S file as follow to exploit the tail
call and improve readability.  It passed nptl/tst-cancel31:

#include <sysdep.h>
#include <descr-const.h>

ENTRY (__syscall_cancel_arch)

	.global __syscall_cancel_arch_start
__syscall_cancel_arch_start:

	/* if (*cancelhandling & CANCELED_BITMASK)
	     __syscall_do_cancel()  */
	ld.w	t0, a0, 0
	andi	t0, t0, TCB_CANCELED_BITMASK
	bnez	t0, 1f

	/* Issue a 6 argument syscall.  */
	move	t1, a1
	move	a0, a2
	move	a1, a3
	move	a2, a4
	move	a3, a5
	move	a4, a6
	move	a5, a7
	move	a7, t1
	syscall 0

	.global __syscall_cancel_arch_end
__syscall_cancel_arch_end:
	jr	ra
1:
	b	__syscall_do_cancel

END (__syscall_cancel_arch)

> 

-- 
Xi Ruoyao <xry111@xry111.site>
School of Aerospace Science and Technology, Xidian University